Go to the first, previous, next, last section, table of contents.

Windows

This chapter describes most of the functions and variables related to Emacs windows. See section Emacs Display, for information on how text is displayed in windows.

Basic Concepts of Emacs Windows

A window is the physical area of the screen in which a buffer is displayed. The term is also used to refer to a Lisp object which represents that screen area in Emacs Lisp. It should be clear from the context which is meant.

There is always at least one window in any frame. In each frame, at any time, one and only one window is designated as selected within the frame. The frame's cursor appears in that window. There is also one selected frame; and the window selected within that frame is the selected window. The selected window's buffer is usually the current buffer (except when set-buffer has been used). See section The Current Buffer.

For all intents, a window only exists while it is displayed on the terminal. Once removed from the display, the window is effectively deleted and should not be used, even though there may still be references to it from other Lisp objects. Restoring a saved window configuration is the only way for a window no longer on the screen to come back to life. (See section Deleting Windows.)

Each window has the following attributes:

Users create multiple windows so they can look at several buffers at once. Lisp libraries use multiple windows for a variety of reasons, but most often to give different views of the same information. In Rmail, for example, you can move through a summary buffer in one window while the other window shows messages one at a time as they are reached.

The meaning of "window" in Emacs is similar to what it means in the context of general purpose window systems such as X, but not identical. The X Window System subdivides the screen into X windows; Emacs uses one or more X windows, called frames in Emacs terminology, and subdivides each of them into (nonoverlapping) Emacs windows. When you use Emacs on an ordinary display terminal, Emacs subdivides the terminal screen into Emacs windows.

Most window systems support arbitrarily located overlapping windows. In contrast, Emacs windows are tiled; they never overlap, and together they fill the whole of the screen or frame. Because of the way in which Emacs creates new windows and resizes them, you can't create every conceivable tiling of windows on an Emacs frame. See section Splitting Windows, and section The Size of a Window.

See section Emacs Display, for information on how the contents of the window's buffer are displayed in the window.

Function: windowp object
This function returns t if object is a window.

Splitting Windows

The functions described here are the primitives used to split a window into two windows. Two higher level functions sometimes split a window, but not always: pop-to-buffer and display-buffer (see section Displaying Buffers in Windows).

The functions described here do not accept a buffer as an argument. The two "halves" of the split window initially display the same buffer previously visible in the window that was split.

Command: split-window &optional window size horizontal
This function splits window into two windows. The original window window remains the selected window, but occupies only part of its former screen area. The rest is occupied by a newly created window which is returned as the value of this function.

If horizontal is non-nil, then window splits into two side by side windows. The original window window keeps the leftmost size columns, and gives the rest of the columns to the new window. Otherwise, it splits into windows one above the other, and window keeps the upper size lines and gives the rest of the lines to the new window. The original window is therefore the right-hand or upper of the two, and the new window is the left-hand or lower.

If window is omitted or nil, then the selected window is split. If size is omitted or nil, then window is divided evenly into two parts. (If there is an odd line, it is allocated to the new window.) When split-window is called interactively, all its arguments are nil.

The following example starts with one window on a screen that is 50 lines high by 80 columns wide; then the window is split. 

(setq w (selected-window))
     => #<window 8 on windows.texi>
(window-edges)          ; Edges in order:
     => (0 0 80 50)     ;   left--top--right--bottom

;; Returns window created
(setq w2 (split-window w 15))   
     => #<window 28 on windows.texi>
(window-edges w2)
     => (0 15 80 50)    ; Bottom window;
                        ;   top is line 15
(window-edges w)
     => (0 0 80 15)     ; Top window

The screen looks like this: 

         __________ 
        |          |  line 0  
        |    w     |
        |__________|
        |          |  line 15
        |    w2    |
        |__________|
                      line 50
 column 0   column 80

Next, the top window is split horizontally: 

(setq w3 (split-window w 35 t))
     => #<window 32 on windows.texi>
(window-edges w3)
     => (35 0 80 15)  ; Left edge at column 35
(window-edges w)
     => (0 0 35 15)   ; Right edge at column 35
(window-edges w2)
     => (0 15 80 50)  ; Bottom window unchanged

Now, the screen looks like this: 

     column 35
         __________ 
        |   |      |  line 0  
        | w |  w3  |
        |___|______|
        |          |  line 15
        |    w2    |
        |__________|
                      line 50
 column 0   column 80

Command: split-window-vertically size
This function splits the selected window into two windows, one above the other, leaving the selected window with size lines.

This function is simply an interface to split-windows. Here is the complete function definition for it: 

(defun split-window-vertically (&optional arg)
  "Split current window into two windows, one above the other."
  (interactive "P")
  (split-window nil (and arg (prefix-numeric-value arg))))

Command: split-window-horizontally size
This function splits the selected window into two windows side-by-side, leaving the selected window with size columns.

This function is simply an interface to split-windows. Here is the complete definition for split-window-horizontally (except for part of the documentation string): 

(defun split-window-horizontally (&optional arg)
  "Split selected window into two windows, side by side..."
  (interactive "P")
  (split-window nil (and arg (prefix-numeric-value arg)) t))

Function: one-window-p &optional no-mini all-frames
This function returns non-nil if there is only one window. The argument no-mini, if non-nil, means don't count the minibuffer even if it is active; otherwise, the minibuffer window is included, if active, in the total number of windows which is compared against one.

The argument all-frames specifies which frames to consider. Here are the possible values and their meanings:

nil
Count the windows in the selected frame, plus the minibuffer used by that frame even if it lies in some other frame.
t
Count all windows in all existing frames.
visible
Count all windows in all visible frames.
anything else
Count precisely the windows in the selected frame, and no others.

Deleting Windows

A window remains visible on its frame unless you delete it by calling certain functions that delete windows. A deleted window cannot appear on the screen, but continues to exist as a Lisp object until there are no references to it. There is no way to cancel the deletion of a window aside from restoring a saved window configuration (see section Window Configurations). Restoring a window configuration also deletes any windows that aren't part of that configuration.

When you delete a window, the space it took up is given to one adjacent sibling. (In Emacs version 18, the space was divided evenly among all the siblings.)

Function: window-live-p window
This function returns nil if window is deleted, and t otherwise.

Warning: erroneous information or fatal errors may result from using a deleted window as if it were live.

Command: delete-window &optional window
This function removes window from the display. If window is omitted, then the selected window is deleted. An error is signaled if there is only one window when delete-window is called.

This function returns nil.

When delete-window is called interactively, window defaults to the selected window.

Command: delete-other-windows &optional window
This function makes window the only window on its frame, by deleting the other windows in that frame. If window is omitted or nil, then the selected window is used by default.

The result is nil.

Command: delete-windows-on buffer &optional frame
This function deletes all windows showing buffer. If there are no windows showing buffer, it does nothing.

delete-windows-on operates frame by frame. If a frame has several windows showing different buffers, then those showing buffer are removed, and the others expand to fill the space. If all windows in some frame are showing buffer (including the case where there is only one window), then the frame reverts to having a single window showing another buffer chosen with other-buffer. See section The Buffer List.

The argument frame controls which frames to operate on:

This function always returns nil.

Selecting Windows

When a window is selected, the buffer in the window becomes the current buffer, and the cursor will appear in it.

Function: selected-window
This function returns the selected window. This is the window in which the cursor appears and to which many commands apply.

Function: select-window window
This function makes window the selected window. The cursor then appears in window (on redisplay). The buffer being displayed in window is immediately designated the current buffer.

The return value is window. 

(setq w (next-window))
(select-window w)
     => #<window 65 on windows.texi>

The following functions choose one of the windows on the screen, offering various criteria for the choice.

Function: get-lru-window &optional frame
This function returns the window least recently "used" (that is, selected). The selected window is always the most recently used window.

The selected window can be the least recently used window if it is the only window. A newly created window becomes the least recently used window until it is selected. A minibuffer window is never a candidate.

The argument frame controls which set of windows are considered.

Function: get-largest-window &optional frame
This function returns the window with the largest area (height times width). If there are no side-by-side windows, then this is the window with the most lines. A minibuffer window is never a candidate.

If there are two windows of the same size, then the function returns the window which is first in the cyclic ordering of windows (see following section), starting from the selected window.

The argument frame controls which set of windows are considered. See get-lru-window, above.

Cyclic Ordering of Windows

When you use the command C-x o (other-window) to select the next window, it moves through all the windows on the screen in a specific cyclic order. For any given configuration of windows, this order never varies. It is called the cyclic ordering of windows.

This ordering generally goes from top to bottom, and from left to right. But it may go down first or go right first, depending on the order in which the windows were split.

If the first split was vertical (into windows one above each other), and then the subwindows were split horizontally, then the ordering is left to right in the top of the frame, and then left to right in the next lower part of the frame, and so on. If the first split was horizontal, the ordering is top to bottom in the left part, and so on. In general, within each set of siblings at any level in the window tree, the order is left to right, or top to bottom.

Function: next-window &optional window minibuf all-frames
This function returns the window following window in the cyclic ordering of windows. This is the window which C-x o would select if done when window is selected. If window is the only window visible, then this function returns window. If omitted, window defaults to the selected window.

The value of the argument minibuf determines whether the minibuffer is included in the window order. Normally, when minibuf is nil, the minibuffer is included if it is currently active; this is the behavior of C-x o. (The minibuffer window is active while the minibuffer is in use. See section Minibuffers.)

If minibuf is t, then the cyclic ordering includes the minibuffer window even if it is not active.

If minibuf is neither t nor nil, then the minibuffer window is not included even if it is active.

The argument all-frames specifies which frames to consider. Here are the possible values and their meanings:

nil
Consider all the windows in window's frame, plus the minibuffer used by that frame even if it lies in some other frame.
t
Consider all windows in all existing frames.
visible
Consider all windows in all visible frames. (To get useful results, you must ensure window is in a visible frame.)
anything else
Consider precisely the windows in window's frame, and no others.

This example assumes there are two windows, both displaying the buffer `windows.texi': 

(selected-window)
     => #<window 56 on windows.texi>
(next-window (selected-window))
     => #<window 52 on windows.texi>
(next-window (next-window (selected-window)))
     => #<window 56 on windows.texi>

Function: previous-window &optional window minibuf all-frames
This function returns the window preceding window in the cyclic ordering of windows. The other arguments specify which windows to include in the cycle, as in next-window.

Command: other-window count
This function selects the countth following window in the cyclic order. If count is negative, then it selects the -countth preceding window. It returns nil.

In an interactive call, count is the numeric prefix argument.

Function: walk-windows proc &optional minibuf all-frames
This function cycles through all windows, calling proc once for each window with the window as its sole argument.

The optional arguments minibuf and all-frames specify the set of windows to include in the scan. See next-window, above, for details.

Buffers and Windows

This section describes low-level functions to examine windows or to display buffers in windows in a precisely controlled fashion. See the following section for related functions that find a window to use and specify a buffer for it. The functions described there are easier to use than these, but they employ heuristics in choosing or creating a window; use these functions when you need complete control.

Function: set-window-buffer window buffer-or-name
This function makes window display buffer-or-name as its contents. It returns nil. 

(set-window-buffer (selected-window) "foo")
     => nil

Function: window-buffer &optional window
This function returns the buffer that window is displaying. If window is omitted, this function returns the buffer for the selected window. 

(window-buffer)
     => #<buffer windows.texi>

Function: get-buffer-window buffer-or-name &optional all-frames
This function returns a window currently displaying buffer-or-name, or nil if there is none. If there are several such windows, then the function returns the first one in the cyclic ordering of windows, starting from the selected window. See section Cyclic Ordering of Windows.

The argument all-frames controls which windows to consider.

Command: replace-buffer-in-windows buffer
This function replaces buffer with some other buffer in all windows displaying it. The other buffer used is chosen with other-buffer. In the usual applications of this function, you don't care which other buffer is used; you just want to make sure that buffer is no longer displayed.

This function returns nil.

Displaying Buffers in Windows

In this section we describe convenient functions that choose a window automatically and use it to display a specified buffer. These functions can also split an existing window in certain circumstances. We also describe variables that parameterize the heuristics used for choosing a window. See the preceding section for low-level functions that give you more precise control.

Do not use the functions in this section in order to make a buffer current so that a Lisp program can access or modify it; they are too drastic for that purpose, since they change the display of buffers in windows, which is gratuitous and will surprise the user. Instead, use set-buffer (see section The Current Buffer) and save-excursion (see section Excursions), which designate buffers as current for programmed access without affecting the display of buffers in windows.

Command: switch-to-buffer buffer-or-name &optional norecord
This function makes buffer-or-name the current buffer, and also displays the buffer in the selected window. This means that a human can see the buffer and subsequent keyboard commands will apply to it. Contrast this with set-buffer, which makes buffer-or-name the current buffer but does not display it in the selected window. See section The Current Buffer.

If buffer-or-name does not identify an existing buffer, then a new buffer by that name is created.

Normally the specified buffer is put at the front of the buffer list. This affects the operation of other-buffer. However, if norecord is non-nil, this is not done. See section The Buffer List.

The switch-to-buffer function is often used interactively, as the binding of C-x b. It is also used frequently in programs. It always returns nil.

Command: switch-to-buffer-other-window buffer-or-name
This function makes buffer-or-name the current buffer and displays it in a window not currently selected. It then selects that window. The handling of the buffer is the same as in switch-to-buffer.

The previously selected window is absolutely never used to display the buffer. If it is the only window, then it is split to make a distinct window for this purpose. If the selected window is already displaying the buffer, then it continues to do so, but another window is nonetheless found to display it in as well.

Function: pop-to-buffer buffer-or-name &optional other-window
This function makes buffer-or-name the current buffer and switches to it in some window, preferably not the window previously selected. The "popped-to" window becomes the selected window within its frame.

If the variable pop-up-frames is non-nil, pop-to-buffer looks for a window in any visible frame already displaying the buffer; if there is one, it returns that window and makes it be selected within its frame. If there is none, it creates a new frame and displays the buffer in it.

If pop-up-frames is nil, then pop-to-buffer operates entirely within the selected frame. (If the selected frame has just a minibuffer, pop-to-buffer operates within the most recently selected frame that was not just a minibuffer.)

If the variable pop-up-windows is non-nil, windows may be split to create a new window that is different from the original window. For details, see section Choosing a Window for Display.

If other-window is non-nil, pop-to-buffer finds or creates another window even if buffer-or-name is already visible in the selected window. Thus buffer-or-name could end up displayed in two windows. On the other hand, if buffer-or-name is already displayed in the selected window and other-window is nil, then the selected window is considered sufficient display for buffer-or-name, so that nothing needs to be done.

If buffer-or-name is a string that does not name an existing buffer, a buffer by that name is created.

An example use of this function is found at the end of section Process Filter Functions.

Choosing a Window for Display

This section describes the basic facility which chooses a window to display a buffer in---display-buffer. All the higher-level functions and commands use this subroutine. Here we describe how to use display-buffer and how to customize it.

Command: display-buffer buffer-or-name &optional not-this-window
This command makes buffer-or-name appear in some window, like pop-to-buffer, but it does not select that window and does not make the buffer current. The identity of the selected window is unaltered by this function.

If not-this-window is non-nil, it means to display the specified buffer in a window other than the selected one, even if it is already on display in the selected window. This can cause the buffer to appear in two windows at once. Otherwise, if buffer-or-name is already being displayed in any window, that is good enough, so this function does nothing.

display-buffer returns the window chosen to display buffer-or-name.

Precisely how display-buffer finds or creates a window depends on the variables described below.

User Option: pop-up-windows
This variable controls whether display-buffer makes new windows. If it is non-nil and there is only one window, then that window is split. If it is nil, then display-buffer does not split the single window, but uses it whole.

User Option: split-height-threshold
This variable determines when display-buffer may split a window, if there are multiple windows. display-buffer always splits the largest window if it has at least this many lines. If the largest window is not this tall, it is split only if it is the sole window and pop-up-windows is non-nil.

User Option: pop-up-frames
This variable controls whether display-buffer makes new frames. If it is non-nil, display-buffer looks for an existing window already displaying the desired buffer, on any visible frame. If it finds one, it returns that window. Otherwise it makes a new frame. The variables pop-up-windows and split-height-threshold do not matter if pop-up-frames is non-nil.

If pop-up-frames is nil, then display-buffer either splits a window or reuses one.

See section Frames, for more information.

Variable: pop-up-frame-function
This variable specifies how to make a new frame if pop-up-frames is non-nil.

Its value should be a function of no arguments. When display-buffer makes a new frame, it does so by calling that function, which should return a frame. The default value of the variable is a function which creates a frame using parameters from pop-up-frame-alist.

Variable: pop-up-frame-alist
This variable holds an alist specifying frame parameters used when display-buffer makes a new frame. See section Frame Parameters, for more information about frame parameters.

Variable: special-display-buffer-names
A list of buffer names for buffers that should be displayed specially. If the buffer's name is in this list, display-buffer handles the buffer specially.

By default, special display means to give the buffer a dedicated frame.

Variable: special-display-regexps
A list of regular expressions that specify buffers that should be displayed specially. If the buffer's name matches any of the regular expressions in this list, display-buffer handles the buffer specially.

By default, special display means to give the buffer a dedicated frame.

Variable: special-display-function
This variable holds the function to call to display a buffer specially. It receives the buffer as an argument, and should return the window in which it is displayed.

The default value of this variable is special-display-popup-frame.

Function: special-display-popup-frame buffer
This function makes buffer visible in a frame of its own. If buffer is already displayed in a window in some frame, it makes the frame visible and raises it, to use that window. Otherwise, it creates a frame that will be dedicated to buffer.

User Option: special-display-frame-alist
This variable holds frame parameters for special-display-popup-frame to use when it creates a frame.

Variable: display-buffer-function
This variable is the most flexible way to customize the behavior of display-buffer. If it is non-nil, it should be a function that display-buffer calls to do the work. The function should accept two arguments, the same two arguments that display-buffer received. It should choose or create a window, display the specified buffer, and then return the window.

This hook takes precedence over all the other options and hooks described above.

A window can be marked as "dedicated" to its buffer. Then display-buffer does not try to use that window.

Function: window-dedicated-p window
This function returns t if window is marked as dedicated; otherwise nil.

Function: set-window-dedicated-p window flag
This function marks window as dedicated if flag is non-nil, and nondedicated otherwise.

Windows and Point

Each window has its own value of point, independent of the value of point in other windows displaying the same buffer. This makes it useful to have multiple windows showing one buffer.

As far as the user is concerned, point is where the cursor is, and when the user switches to another buffer, the cursor jumps to the position of point in that buffer.

Function: window-point window
This function returns the current position of point in window. For a nonselected window, this is the value point would have (in that window's buffer) if that window were selected.

When window is the selected window and its buffer is also the current buffer, the value returned is the same as point in that buffer.

Strictly speaking, it would be more correct to return the "top-level" value of point, outside of any save-excursion forms. But that value is hard to find.

Function: set-window-point window position
This function positions point in window at position position in window's buffer.

The Window Start Position

Each window contains a marker used to keep track of a buffer position which specifies where in the buffer display should start. This position is called the display-start position of the window (or just the start). The character after this position is the one that appears at the upper left corner of the window. It is usually, but not inevitably, at the beginning of a text line.

Function: window-start &optional window
This function returns the display-start position of window window. If window is nil, the selected window is used. For example, 

(window-start)
     => 7058

When you create a window, or display a different buffer in it, the the display-start position is set to a display-start position recently used for the same buffer, or 1 if the buffer doesn't have any.

For a realistic example, see the description of count-lines in section Motion by Text Lines.

Function: window-end &optional window
This function returns the position of the end of the display in window window. If window is nil, the selected window is used.

Function: set-window-start window position &optional noforce
This function sets the display-start position of window to position in window's buffer.

The display routines insist that the position of point be visible when a buffer is displayed. Normally, they change the display-start position (that is, scroll the window) whenever necessary to make point visible. However, if you specify the start position with this function using nil for noforce, it means you want display to start at position even if that would put the location of point off the screen. If this does place point off screen, the display routines move point to the left margin on the middle line in the window.

For example, if point is 1 and you set the start of the window to 2, then point would be "above" the top of the window. The display routines will automatically move point if it is still 1 when redisplay occurs. Here is an example: 

;; Here is what `foo' looks like before executing
;;   the set-window-start expression.

---------- Buffer: foo ----------
-!-This is the contents of buffer foo.
2
3
4
5
6
---------- Buffer: foo ----------

(set-window-start
 (selected-window)
 (1+ (window-start)))
=> 2

;; Here is what `foo' looks like after executing
;;   the set-window-start expression.
---------- Buffer: foo ----------
his is the contents of buffer foo.
2
3
-!-4
5
6
---------- Buffer: foo ----------

If noforce is non-nil, and position would place point off screen at the next redisplay, then redisplay computes a new window-start position that works well with point, and thus position is not used.

This function returns position.

Function: pos-visible-in-window-p &optional position window
This function returns t if position is within the range of text currently visible on the screen in window. It returns nil if position is scrolled vertically out of view. The argument position defaults to the current position of point; window, to the selected window. Here is an example: 

(or (pos-visible-in-window-p
     (point) (selected-window))
    (recenter 0))

The pos-visible-in-window-p function considers only vertical scrolling. If position is out of view only because window has been scrolled horizontally, pos-visible-in-window-p returns t. See section Horizontal Scrolling.

Vertical Scrolling

Vertical scrolling means moving the text up or down in a window. It works by changing the value of the window's display-start location. It may also change the value of window-point to keep it on the screen.

In the commands scroll-up and scroll-down, the directions "up" and "down" refer to the motion of the text in the buffer at which you are looking through the window. Imagine that the text is written on a long roll of paper and that the scrolling commands move the paper up and down. Thus, if you are looking at text in the middle of a buffer and repeatedly call scroll-down, you will eventually see the beginning of the buffer.

Some people have urged that the opposite convention be used: they imagine that the window moves over text that remains in place. Then "down" commands would take you to the end of the buffer. This view is more consistent with the actual relationship between windows and the text in the buffer, but it is less like what the user sees. The position of a window on the terminal does not move, and short scrolling commands clearly move the text up or down on the screen. We have chosen names that fit the user's point of view.

The scrolling functions (aside from scroll-other-window) have unpredictable results if the current buffer is different from the buffer that is displayed in the selected window. See section The Current Buffer.

Command: scroll-up &optional count
This function scrolls the text in the selected window upward count lines. If count is negative, scrolling is actually downward.

If count is nil (or omitted), then the length of scroll is next-screen-context-lines lines less than the usable height of the window (not counting its mode line).

scroll-up returns nil.

Command: scroll-down &optional count
This function scrolls the text in the selected window downward count lines. If count is negative, scrolling is actually upward.

If count is omitted or nil, then the length of the scroll is next-screen-context-lines lines less than the usable height of the window.

scroll-down returns nil.

Command: scroll-other-window &optional count
This function scrolls the text in another window upward count lines. Negative values of count, or nil, are handled as in scroll-up.

The window that is scrolled is normally the one following the selected window in the cyclic ordering of windows--the window that next-window would return. See section Cyclic Ordering of Windows.

You can specify a buffer to scroll with the variable other-window-scroll-buffer. When the selected window is the minibuffer, the next window is normally the one at the top left corner. You can specify a different window to scroll with the variable minibuffer-scroll-window. This variable has no effect when any other window is selected. See section Minibuffer Miscellany.

When the minibuffer is active, it is the next window if the selected window is the one at the bottom right corner. In this case, scroll-other-window attempts to scroll the minibuffer. If the minibuffer contains just one line, it has nowhere to scroll to, so the line reappears after the echo area momentarily displays the message "Beginning of buffer".

Variable: other-window-scroll-buffer
If this variable is non-nil, it tells scroll-other-window which buffer to scroll.

User Option: scroll-step
This variable controls how scrolling is done automatically when point moves off the screen. If the value is zero, then redisplay scrolls the text to center point vertically in the window. If the value is a positive integer n, then redisplay brings point back on screen by scrolling n lines in either direction, if possible; otherwise, it centers point if possible. The default value is zero.

User Option: next-screen-context-lines
The value of this variable is the number of lines of continuity to retain when scrolling by full screens. For example, scroll-up with an argument of nil scrolls so that this many lines at the bottom of the window appear instead at the top. The default value is 2.

Command: recenter &optional count
This function scrolls the selected window to put the text where point is located at a specified vertical position within the window.

If count is a nonnegative number, it puts the line containing point count lines down from the top of the window. If count is a negative number, then it counts upward from the bottom of the window, so that -1 stands for the last usable line in the window. If count is a non-nil list, then it stands for the line in the middle of the window.

If count is nil, recenter puts the line containing point in the middle of the window, then clears and redisplays the entire selected frame.

When recenter is called interactively, count is the raw prefix argument. Thus, typing C-u as the prefix sets the count to a non-nil list, while typing C-u 4 sets count to 4, which positions the current line four lines from the top.

Typing C-u 0 C-l positions the current line at the top of the window. This action is so handy that some people bind the command to a function key. For example, 

(defun line-to-top-of-window ()
  "Scroll current line to top of window.
Replaces three keystroke sequence C-u 0 C-l."
  (interactive) 
  (recenter 0))

(global-set-key "\C-cl" 'line-to-top-of-window)

Horizontal Scrolling

Because we read English first from top to bottom and second from left to right, horizontal scrolling is not like vertical scrolling. Vertical scrolling involves selection of a contiguous portion of text to display. Horizontal scrolling causes part of each line to go off screen. The amount of horizontal scrolling is therefore specified as a number of columns rather than as a position in the buffer. It has nothing to do with the display-start position returned by window-start.

Usually, no horizontal scrolling is in effect; then the leftmost column is at the left edge of the window. In this state, scrolling to the right is meaningless, since there is no data to the left of the screen to be revealed by it; so this is not allowed. Scrolling to the left is allowed; it scrolls the first columns of text off the edge of the window and can reveal additional columns on the right that were truncated before. Once a window has a nonzero amount of leftward horizontal scrolling, you can scroll it back to the right, but only so far as to reduce the net horizontal scroll to zero. There is no limit to how far left you can scroll, but eventually all the text will disappear off the left edge.

Command: scroll-left count
This function scrolls the selected window count columns to the left (or to the right if count is negative). The return value is the total amount of leftward horizontal scrolling in effect after the change--just like the value returned by window-hscroll.

Command: scroll-right count
This function scrolls the selected window count columns to the right (or to the left if count is negative). The return value is the total amount of leftward horizontal scrolling in effect after the change--just like the value returned by window-hscroll.

Once you scroll a window as far right as it can go, back to its normal position where the total leftward scrolling is zero, attempts to scroll any farther right have no effect.

Function: window-hscroll &optional window
This function returns the total leftward horizontal scrolling of window---the number of columns by which the text in window is scrolled left past the left margin.

The value is never negative. It is zero when no horizontal scrolling has been done in window (which is usually the case).

If window is nil, the selected window is used. 

(window-hscroll)
     => 0
(scroll-left 5)
     => 5
(window-hscroll)
     => 5

Function: set-window-hscroll window columns
This function sets the number of columns from the left margin that window is scrolled to the value of columns. The argument columns should be zero or positive; if not, it is taken as zero.

The value returned is columns. 

(set-window-hscroll (selected-window) 10)
     => 10

Here is how you can determine whether a given position position is off the screen due to horizontal scrolling: 

(save-excursion 
  (goto-char position)
  (and 
   (>= (- (current-column) (window-hscroll window)) 0)
   (< (- (current-column) (window-hscroll window))
      (window-width window))))

The Size of a Window

An Emacs window is rectangular, and its size information consists of the height (the number of lines) and the width (the number of character positions in each line). The mode line is included in the height. But the width does not count the scroll bar or the column of `|' characters separates side-by-side windows.

The following three functions return size information about a window:

Function: window-height &optional window
This function returns the number of lines in window, including its mode line. If window fills its entire frame, this is one less than the value of frame-height on that frame (since the last line is always reserved for the minibuffer).

If window is nil, the function uses the selected window. 

(window-height)
     => 23
(split-window-vertically)
     => #<window 4 on windows.texi>
(window-height)
     => 11

Function: window-width &optional window
This function returns the number of columns in window. If window fills its entire frame, this is the same as the value of frame-width on that frame. The width does not include the window's scroll bar or the column of `|' characters that separates side-by-side windows.

If window is nil, the function uses the selected window. 

(window-width)
     => 80

Function: window-edges &optional window
This function returns a list of the edge coordinates of window. If window is nil, the selected window is used.

The order of the list is (left top right bottom), all elements relative to 0, 0 at the top left corner of the frame. The element right of the value is one more than the rightmost column used by window, and bottom is one more than the bottommost row used by window and its mode-line.

When you have side-by-side windows, the right edge value for a window with a neighbor on the right includes the width of the separator between the window and that neighbor. This separator may be a column of `|' characters or it may be a scroll bar. Since the width of the window does not include this separator, the width does not equal the difference between the right and left edges in this case.

Here is the result obtained on a typical 24-line terminal with just one window: 

(window-edges (selected-window))
     => (0 0 80 23)

If window is at the upper left corner of its frame, right and bottom are the same as the values returned by (window-width) and (window-height) respectively, and top and bottom are zero. For example, the edges of the following window are `0 0 5 8'. Assuming that the frame has more than 8 columns, the last column of the window (column 7) holds a border rather than text. The last row (row 4) holds the mode line, shown here with `xxxxxxxxx'. 

           0    
           _______
        0 |       | 
          |       |   
          |       | 
          |       | 
          xxxxxxxxx  4

                  7

When there are side-by-side windows, any window not at the right edge of its frame has a separator in its last column or columns. The separator counts as one or two columns in the width of the window. A window never includes a separator on its left, since that belongs to the window to the left.

In the following example, let's suppose that the frame is 7 columns wide. Then the edges of the left window are `0 0 4 3' and the edges of the right window are `4 0 7 3'. 

           ___ ___
          |   |   |    
          |   |   |    
          xxxxxxxxx 

           0  34  7

Changing the Size of a Window

The window size functions fall into two classes: high-level commands that change the size of windows and low-level functions that access window size. Emacs does not permit overlapping windows or gaps between windows, so resizing one window affects other windows.

Command: enlarge-window size &optional horizontal
This function makes the selected window size lines bigger, stealing lines from neighboring windows. It takes the lines from one window at a time until that window is used up, then takes from another. If a window from which lines are stolen shrinks below window-min-height lines, that window disappears.

If horizontal is non-nil, this function makes window wider by size columns, stealing columns instead of lines. If a window from which columns are stolen shrinks below window-min-width columns, that window disappears.

If the window's frame is smaller than size lines (or columns), then the function makes the window occupy the entire height (or width) of the frame.

If size is negative, this function shrinks the window by -size lines or columns. If that makes the window smaller than the minimum size (window-min-height and window-min-width), enlarge-window deletes the window.

enlarge-window returns nil.

Command: enlarge-window-horizontally columns
This function makes the selected window columns wider. It could be defined as follows: 

(defun enlarge-window-horizontally (columns)
  (enlarge-window columns t))

Command: shrink-window size &optional horizontal
This function is like enlarge-window but negates the argument size, making the selected window smaller by giving lines (or columns) to the other windows. If the window shrinks below window-min-height or window-min-width, then it disappears.

If size is negative, the window is enlarged by -size lines or columns.

Command: shrink-window-horizontally columns
This function makes the selected window columns narrower. It could be defined as follows: 

(defun shrink-window-horizontally (columns)
  (shrink-window columns t))

The following two variables constrain the window size changing functions to a minimum height and width.

User Option: window-min-height
The value of this variable determines how short a window may become before it is automatically deleted. Making a window smaller than window-min-height automatically deletes it, and no window may be created shorter than this. The absolute minimum height is two (allowing one line for the mode line, and one line for the buffer display). Actions which change window sizes reset this variable to two if it is less than two. The default value is 4.

User Option: window-min-width
The value of this variable determines how narrow a window may become before it automatically deleted. Making a window smaller than window-min-width automatically deletes it, and no window may be created narrower than this. The absolute minimum width is one; any value below that is ignored. The default value is 10.

Coordinates and Windows

This section describes how to compare screen coordinates with windows.

Function: window-at x y &optional frame
This function returns the window containing the specified cursor position in the frame frame. The coordinates x and y are measured in characters and count from the top left corner of the frame. If they are out of range, window-at returns nil.

If you omit frame, the selected frame is used.

Function: coordinates-in-window-p coordinates window
This function checks whether a particular frame position falls within the window window.

The argument coordinates is a cons cell of this form: 

(x . y)

The coordinates x and y are measured in characters, and count from the top left corner of the screen or frame.

The value of coordinates-in-window-p is non-nil if the coordinates are inside window. The value also indicates what part of the window the position is in, as follows:

(relx . rely)
The coordinates are inside window. The numbers relx and rely are the equivalent window-relative coordinates for the specified position, counting from 0 at the top left corner of the window.
mode-line
The coordinates are in the mode line of window.
vertical-split
The coordinates are in the vertical line between window and its neighbor to the right. This value occurs only if the window doesn't have a scroll bar; positions in a scroll bar are considered outside the window.
nil
The coordinates are not in any part of window.

The function coordinates-in-window-p does not require a frame as argument because it always uses the frame that window is on.

Window Configurations

A window configuration records the entire layout of a frame--all windows, their sizes, which buffers they contain, what part of each buffer is displayed, and the values of point and the mark. You can bring back an entire previous layout by restoring a window configuration previously saved.

If you want to record all frames instead of just one, use a frame configuration instead of a window configuration. See section Frame Configurations.

Function: current-window-configuration
This function returns a new object representing Emacs's current window configuration, namely the number of windows, their sizes and current buffers, which window is the selected window, and for each window the displayed buffer, the display-start position, and the positions of point and the mark. An exception is made for point in the current buffer, whose value is not saved.

Function: set-window-configuration configuration
This function restores the configuration of Emacs's windows and buffers to the state specified by configuration. The argument configuration must be a value that was previously returned by current-window-configuration.

Here is a way of using this function to get the same effect as save-window-excursion: 

(let ((config (current-window-configuration)))
  (unwind-protect
      (progn (split-window-vertically nil)
             ...)
    (set-window-configuration config)))

Special Form: save-window-excursion forms...
This special form records the window configuration, executes forms in sequence, then restores the earlier window configuration. The window configuration includes the value of point and the portion of the buffer which is visible. It also includes the choice of selected window. However, it does not include the value of point in the current buffer; use save-excursion if you wish to preserve that.

The return value is the value of the final form in forms. For example: 

(split-window)
     => #<window 25 on control.texi>
(setq w (selected-window))
     => #<window 19 on control.texi>
(save-window-excursion
  (delete-other-windows w)
  (switch-to-buffer "foo")
  'do-something)
     => do-something
     ;; The screen is now split again.

Function: window-configuration-p object
This function returns t if object is a window configuration.

Primitives to look inside of window configurations would make sense, but none are implemented. It is not clear they are useful enough to be worth implementing.

Go to the first, previous, next, last section, table of contents.