Go to the first, previous, next, last section, table of contents.

Major and Minor Modes

A mode is a set of definitions that customize Emacs and can be turned on and off while you edit. There are two varieties of modes: major modes, which are mutually exclusive and used for editing particular kinds of text, and minor modes, which provide features that users can enable individually.

This chapter describes how to write both major and minor modes, how to indicate them in the mode line, and how they run hooks supplied by the user. For related topics such as keymaps and syntax tables, see section Keymaps, and section Syntax Tables.

Major Modes: Defining major modes.
Minor Modes: Defining minor modes.
Mode Line Format: Customizing the text that appears in the mode line.
Hooks: How to use hooks; how to write code that provides hooks.

Major Modes

Major modes specialize Emacs for editing particular kinds of text. Each buffer has only one major mode at a time.

The least specialized major mode is called Fundamental mode. This mode has no mode-specific definitions or variable settings, so each Emacs command behaves in its default manner, and each option is in its default state. All other major modes redefine various keys and options. For example, Lisp Interaction mode provides special key bindings for LFD (eval-print-last-sexp), TAB (lisp-indent-line), and other keys.

When you need to write several editing commands to help you perform a specialized editing task, creating a new major mode is usually a good idea. In practice, writing a major mode is easy (in contrast to writing a minor mode, which is often difficult).

If the new mode is similar to an old one, it is often unwise to modify the old one to serve two purposes, since it may become harder to use and maintain. Instead, copy and rename an existing major mode definition and alter the copy--or define a derived mode (see section Defining Derived Modes). For example, Rmail Edit mode, which is in `emacs/lisp/rmailedit.el', is a major mode that is very similar to Text mode except that it provides three additional commands. Its definition is distinct from that of Text mode, but was derived from it.

Rmail Edit mode is an example of a case where one piece of text is put temporarily into a different major mode so it can be edited in a different way (with ordinary Emacs commands rather than Rmail). In such cases, the temporary major mode usually has a command to switch back to the buffer's usual mode (Rmail mode, in this case). You might be tempted to present the temporary redefinitions inside a recursive edit and restore the usual ones when the user exits; but this is a bad idea because it constrains the user's options when it is done in more than one buffer: recursive edits must be exited most-recently-entered first. Using alternative major modes avoids this limitation. See section Recursive Editing.

The standard GNU Emacs Lisp library directory contains the code for several major modes, in files including `text-mode.el', `texinfo.el', `lisp-mode.el', `c-mode.el', and `rmail.el'. You can look at these libraries to see how modes are written. Text mode is perhaps the simplest major mode aside from Fundamental mode. Rmail mode is a complicated and specialized mode.

Major Mode Conventions: Coding conventions for keymaps, etc.
Example Major Modes: Text mode and Lisp modes.
Auto Major Mode: How Emacs chooses the major mode automatically.
Mode Help: Finding out how to use a mode.
Derived Modes: Defining a new major mode based on another major mode.

Major Mode Conventions

The code for existing major modes follows various coding conventions, including conventions for local keymap and syntax table initialization, global names, and hooks. Please follow these conventions when you define a new major mode:

Define a command whose name ends in `-mode', with no arguments, that switches to the new mode in the current buffer. This command should set up the keymap, syntax table, and local variables in an existing buffer without changing the buffer's text.
Write a documentation string for this command that describes the special commands available in this mode. C-h m (describe-mode) in your mode will display this string. The documentation string may include the special documentation substrings, `\[command]', `\{keymap}', and `\<keymap>', that enable the documentation to adapt automatically to the user's own key bindings. See section Substituting Key Bindings in Documentation.
The major mode command should start by calling kill-all-local-variables. This is what gets rid of the local variables of the major mode previously in effect.
The major mode command should set the variable major-mode to the major mode command symbol. This is how describe-mode discovers which documentation to print.
The major mode command should set the variable mode-name to the "pretty" name of the mode, as a string. This appears in the mode line.
Since all global names are in the same name space, all the global variables, constants, and functions that are part of the mode should have names that start with the major mode name (or with an abbreviation of it if the name is long). See section Writing Clean Lisp Programs.
The major mode should usually have its own keymap, which is used as the local keymap in all buffers in that mode. The major mode function should call use-local-map to install this local map. See section Active Keymaps, for more information. This keymap should be kept in a global variable named modename-mode-map. Normally the library that defines the mode sets this variable.
The mode may have its own syntax table or may share one with other related modes. If it has its own syntax table, it should store this in a variable named modename-mode-syntax-table. See section Syntax Tables.
The mode may have its own abbrev table or may share one with other related modes. If it has its own abbrev table, it should store this in a variable named modename-mode-abbrev-table. See section Abbrev Tables.
Use defvar to set mode-related variables, so that they are not reinitialized if they already have a value. (Such reinitialization could discard customizations made by the user.)
To make a buffer-local binding for an Emacs customization variable, use make-local-variable in the major mode command, not make-variable-buffer-local. The latter function would make the variable local to every buffer in which it is subsequently set, which would affect buffers that do not use this mode. It is undesirable for a mode to have such global effects. See section Buffer-Local Variables. It's ok to use make-variable-buffer-local, if you wish, for a variable used only within a single Lisp package.
Each major mode should have a mode hook named modename-mode-hook. The major mode command should run that hook, with run-hooks, as the very last thing it does. See section Hooks.
The major mode command may also run the hooks of some more basic modes. For example, indented-text-mode runs text-mode-hook as well as indented-text-mode-hook. It may run these other hooks immediately before the mode's own hook (that is, after everything else), or it may run them earlier.
If something special should be done if the user switches a buffer from this mode to any other major mode, the mode can set a local value for change-major-mode-hook.
If this mode is appropriate only for specially-prepared text, then the major mode command symbol should have a property named mode-class with value special, put on as follows:
```
(put 'funny-mode 'mode-class 'special)
```
This tells Emacs that new buffers created while the current buffer has Funny mode should not inherit Funny mode. Modes such as Dired, Rmail, and Buffer List use this feature.
If you want to make the new mode the default for files with certain recognizable names, add an element to auto-mode-alist to select the mode for those file names. If you define the mode command to autoload, you should add this element in the same file that calls autoload. Otherwise, it is sufficient to add the element in the file that contains the mode definition. See section How Emacs Chooses a Major Mode.
In the documentation, you should provide a sample autoload form and an example of how to add to auto-mode-alist, that users can include in their `.emacs' files.
The top-level forms in the file defining the mode should be written so that they may be evaluated more than once without adverse consequences. Even if you never load the file more than once, someone else will.

Variable: change-major-mode-hook: This normal hook is run by kill-all-local-variables before it does anything else. This gives major modes a way to arrange for something special to be done if the user switches to a different major mode. For best results, make this variable buffer-local, so that it will disappear after doing its job and will not interfere with the subsequent major mode. See section Hooks.

Major Mode Examples

Text mode is perhaps the simplest mode besides Fundamental mode. Here are excerpts from `text-mode.el' that illustrate many of the conventions listed above:

;; Create mode-specific tables.
(defvar text-mode-syntax-table nil 
  "Syntax table used while in text mode.")

(if text-mode-syntax-table
    ()              ; Do not change the table if it is already set up.
  (setq text-mode-syntax-table (make-syntax-table))
  (modify-syntax-entry ?\" ".   " text-mode-syntax-table)
  (modify-syntax-entry ?\\ ".   " text-mode-syntax-table)
  (modify-syntax-entry ?' "w   " text-mode-syntax-table))

(defvar text-mode-abbrev-table nil
  "Abbrev table used while in text mode.")
(define-abbrev-table 'text-mode-abbrev-table ())

(defvar text-mode-map nil)   ; Create a mode-specific keymap.

(if text-mode-map
    ()              ; Do not change the keymap if it is already set up.
  (setq text-mode-map (make-sparse-keymap))
  (define-key text-mode-map "\t" 'tab-to-tab-stop)
  (define-key text-mode-map "\es" 'center-line)
  (define-key text-mode-map "\eS" 'center-paragraph))

Here is the complete major mode function definition for Text mode:

(defun text-mode ()
  "Major mode for editing text intended for humans to read. 
 Special commands: \\{text-mode-map}
Turning on text-mode runs the hook `text-mode-hook'."
  (interactive)
  (kill-all-local-variables)
  (use-local-map text-mode-map)     ; This provides the local keymap.
  (setq mode-name "Text")           ; This name goes into the mode line.
  (setq major-mode 'text-mode)      ; This is how describe-mode
                                    ;   finds the doc string to print.
  (setq local-abbrev-table text-mode-abbrev-table)
  (set-syntax-table text-mode-syntax-table)
  (run-hooks 'text-mode-hook))      ; Finally, this permits the user to
                                    ;   customize the mode with a hook.

The three Lisp modes (Lisp mode, Emacs Lisp mode, and Lisp Interaction mode) have more features than Text mode and the code is correspondingly more complicated. Here are excerpts from `lisp-mode.el' that illustrate how these modes are written.

;; Create mode-specific table variables.
(defvar lisp-mode-syntax-table nil "")  
(defvar emacs-lisp-mode-syntax-table nil "")
(defvar lisp-mode-abbrev-table nil "")

(if (not emacs-lisp-mode-syntax-table) ; Do not change the table
                                       ;   if it is already set.
    (let ((i 0))
      (setq emacs-lisp-mode-syntax-table (make-syntax-table))

      ;; Set syntax of chars up to 0 to class of chars that are
      ;;   part of symbol names but not words.
      ;;   (The number 0 is 48 in the ASCII character set.)
      (while (< i ?0) 
        (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
        (setq i (1+ i)))
      ...
      ;; Set the syntax for other characters.
      (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
      (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
      ...
      (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
      (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
      ...))
;; Create an abbrev table for lisp-mode.
(define-abbrev-table 'lisp-mode-abbrev-table ())

Much code is shared among the three Lisp modes. The following function sets various variables; it is called by each of the major Lisp mode functions:

(defun lisp-mode-variables (lisp-syntax)
  ;; The lisp-syntax argument is nil in Emacs Lisp mode,
  ;;   and t in the other two Lisp modes.
  (cond (lisp-syntax
         (if (not lisp-mode-syntax-table)
             ;; The Emacs Lisp mode syntax table always exists, but
             ;;   the Lisp Mode syntax table is created the first time a
             ;;   mode that needs it is called.  This is to save space.
             (progn (setq lisp-mode-syntax-table
                       (copy-syntax-table emacs-lisp-mode-syntax-table))
                    ;; Change some entries for Lisp mode.
                    (modify-syntax-entry ?\| "\"   "
                                         lisp-mode-syntax-table)
                    (modify-syntax-entry ?\[ "_   "
                                         lisp-mode-syntax-table)
                    (modify-syntax-entry ?\] "_   "
                                         lisp-mode-syntax-table)))
          (set-syntax-table lisp-mode-syntax-table)))
  (setq local-abbrev-table lisp-mode-abbrev-table)
  ...)

Functions such as forward-paragraph use the value of the paragraph-start variable. Since Lisp code is different from ordinary text, the paragraph-start variable needs to be set specially to handle Lisp. Also, comments are indented in a special fashion in Lisp and the Lisp modes need their own mode-specific comment-indent-function. The code to set these variables is the rest of lisp-mode-variables.

  (make-local-variable 'paragraph-start)
  (setq paragraph-start (concat "^$\\|" page-delimiter))
  ...
  (make-local-variable 'comment-indent-function)
  (setq comment-indent-function 'lisp-comment-indent))

Each of the different Lisp modes has a slightly different keymap. For example, Lisp mode binds C-c C-l to run-lisp, but the other Lisp modes do not. However, all Lisp modes have some commands in common. The following function adds these common commands to a given keymap.

(defun lisp-mode-commands (map)
  (define-key map "\e\C-q" 'indent-sexp)
  (define-key map "\177" 'backward-delete-char-untabify)
  (define-key map "\t" 'lisp-indent-line))

Here is an example of using lisp-mode-commands to initialize a keymap, as part of the code for Emacs Lisp mode. First we declare a variable with defvar to hold the mode-specific keymap. When this defvar executes, it sets the variable to nil if it was void. Then we set up the keymap if the variable is nil.

This code avoids changing the keymap or the variable if it is already set up. This lets the user customize the keymap.

(defvar emacs-lisp-mode-map () "") 
(if emacs-lisp-mode-map
    ()
  (setq emacs-lisp-mode-map (make-sparse-keymap))
  (define-key emacs-lisp-mode-map "\e\C-x" 'eval-defun)
  (lisp-mode-commands emacs-lisp-mode-map))

Finally, here is the complete major mode function definition for Emacs Lisp mode.

(defun emacs-lisp-mode ()
  "Major mode for editing Lisp code to run in Emacs.
Commands:
Delete converts tabs to spaces as it moves back.
Blank lines separate paragraphs.  Semicolons start comments.
\\{emacs-lisp-mode-map}
Entry to this mode runs the hook `emacs-lisp-mode-hook'."
  (interactive)
  (kill-all-local-variables)
  (use-local-map emacs-lisp-mode-map)    ; This provides the local keymap.
  (set-syntax-table emacs-lisp-mode-syntax-table)
  (setq major-mode 'emacs-lisp-mode)     ; This is how describe-mode
                                         ;   finds out what to describe.
  (setq mode-name "Emacs-Lisp")          ; This goes into the mode line.
  (lisp-mode-variables nil)              ; This defines various variables.
  (run-hooks 'emacs-lisp-mode-hook))     ; This permits the user to use a
                                         ;   hook to customize the mode.

How Emacs Chooses a Major Mode

Based on information in the file name or in the file itself, Emacs automatically selects a major mode for the new buffer when a file is visited.

Command: fundamental-mode: Fundamental mode is a major mode that is not specialized for anything in particular. Other major modes are defined in effect by comparison with this one--their definitions say what to change, starting from Fundamental mode. The fundamental-mode function does not run any hooks; you're not supposed to customize it. (If you want Emacs to behave differently in Fundamental mode, change the global state of Emacs.)

Command: normal-mode &optional find-file

This function establishes the proper major mode and local variable bindings for the current buffer. First it calls set-auto-mode, then it runs hack-local-variables to parse, and bind or evaluate as appropriate, any local variables.

If the find-file argument to normal-mode is non-nil, normal-mode assumes that the find-file function is calling it. In this case, it may process a local variables list at the end of the file. The variable enable-local-variables controls whether to do so.

If you run normal-mode interactively, the argument find-file is normally nil. In this case, normal-mode unconditionally processes any local variables list. See section `Local Variables in Files' in The GNU Emacs Manual, for the syntax of the local variables section of a file.

normal-mode uses condition-case around the call to the major mode function, so errors are caught and reported as a `File mode specification error', followed by the original error message.

User Option: enable-local-variables: This variable controls processing of local variables lists in files being visited. A value of t means process the local variables lists unconditionally; nil means ignore them; anything else means ask the user what to do for each file. The default value is t.

User Option: enable-local-eval: This variable controls processing of `Eval:' in local variables lists in files being visited. A value of t means process them unconditionally; nil means ignore them; anything else means ask the user what to do for each file. The default value is maybe.

Function: set-auto-mode: This function selects the major mode that is appropriate for the current buffer. It may base its decision on the value of the `-*-' line, on the visited file name (using auto-mode-alist), or on the value of a local variable. However, this function does not look for the `mode:' local variable near the end of a file; the hack-local-variables function does that. See section `How Major Modes are Chosen' in The GNU Emacs Manual.

User Option: default-major-mode

This variable holds the default major mode for new buffers. The standard value is fundamental-mode.

If the value of default-major-mode is nil, Emacs uses the (previously) current buffer's major mode for the major mode of a new buffer. However, if the major mode symbol has a mode-class property with value special, then it is not used for new buffers; Fundamental mode is used instead. The modes that have this property are those such as Dired and Rmail that are useful only with text that has been specially prepared.

Variable: initial-major-mode: The value of this variable determines the major mode of the initial `*scratch*' buffer. The value should be a symbol that is a major mode command name. The default value is lisp-interaction-mode.

Variable: auto-mode-alist

This variable contains an association list of file name patterns (regular expressions; see section Regular Expressions) and corresponding major mode functions. Usually, the file name patterns test for suffixes, such as `.el' and `.c', but this need not be the case. An ordinary element of the alist looks like

(regexp .
mode-function)

For example,

(("^/tmp/fol/" . text-mode)
 ("\\.texinfo$" . texinfo-mode)
 ("\\.texi$" . texinfo-mode)
 ("\\.el$" . emacs-lisp-mode)
 ("\\.c$" . c-mode) 
 ("\\.h$" . c-mode)
 ...)

When you visit a file whose expanded file name (see section Functions that Expand Filenames) matches a regexp, set-auto-mode calls the corresponding mode-function. This feature enables Emacs to select the proper major mode for most files.

If an element of auto-mode-alist has the form (regexp function t), then after calling function, Emacs searches auto-mode-alist again for a match against the portion of the file name that did not match before.

This match-again feature is useful for uncompression packages: an entry of the form ("\\.gz\\'" . function) can uncompress the file and then put the uncompressed file in the proper mode according to the name sans `.gz'.

Here is an example of how to prepend several pattern pairs to auto-mode-alist. (You might use this sort of expression in your `.emacs' file.)

(setq auto-mode-alist
  (append 
   ;; File name starts with a dot.
   '(("/\\.[^/]*$" . fundamental-mode)  
     ;; File name has no dot.
     ("[^\\./]*$" . fundamental-mode)   
     ;; File name ends in `.C'.
     ("\\.C$" . c++-mode))
   auto-mode-alist))

Variable: interpreter-mode-alist

This variable specifes major modes to use for scripts that specify a command interpreter in an `!#' line. Its value is a list of elements of the form (interpreter . mode); for example, ("perl" . perl-mode) is one element present by default. The element says to use mode mode if the file specifies interpreter.

This variable is applicable only when the auto-mode-alist does not indicate which major mode to use.

Function: hack-local-variables &optional force

This function parses, and binds or evaluates as appropriate, any local variables for the current buffer.

The handling of enable-local-variables documented for normal-mode actually takes place here. The argument force usually comes from the argument find-file given to normal-mode.

Getting Help about a Major Mode

The describe-mode function is used to provide information about major modes. It is normally called with C-h m. The describe-mode function uses the value of major-mode, which is why every major mode function needs to set the major-mode variable.

Command: describe-mode

This function displays the documentation of the current major mode.

The describe-mode function calls the documentation function using the value of major-mode as an argument. Thus, it displays the documentation string of the major mode function. (See section Access to Documentation Strings.)

Variable: major-mode: This variable holds the symbol for the current buffer's major mode. This symbol should have a function definition that is the command to switch to that major mode. The describe-mode function uses the documentation string of the function as the documentation of the major mode.

Defining Derived Modes

It's often useful to define a new major mode in terms of an existing one. An easy way to do this is to use define-derived-mode.

Macro: define-derived-mode variant parent name docstring body...

This construct defines variant as a major mode command, using name as the string form of the mode name.

The new command variant is defined to call the function parent, then override certain aspects of that parent mode:

The new mode has its own keymap, named variant-map. define-derived-mode initializes this map to inherit from parent-map, if it is not already set.
The new mode has its own syntax table, kept in the variable variant-syntax-table. define-derived-mode initializes this variable by copying parent-syntax-table, if it is not already set.
The new mode has its own abbrev table, kept in the variable variant-abbrev-table. define-derived-mode initializes this variable by copying parent-abbrev-table, if it is not already set.
The new mode has its own mode hook, variant-hook, which it runs in standard fashion as the very last thing that it does. (The new mode also runs the mode hook of parent as part of calling parent.)

In addition, you can specify how to override other aspects of parent with body. The command variant evaluates the forms in body after setting up all its usual overrides, just before running variant-hook.

The argument docstring specifies the documentation string for the new mode. If you omit docstring, define-derived-mode generates a documentation string.

Here is a hypothetical example:

(define-derived-mode hypertext-mode
  text-mode "Hypertext"
  "Major mode for hypertext.
\\{hypertext-mode-map}"
  (setq case-fold-search nil))

(define-key hypertext-mode-map
  [down-mouse-3] 'do-hyper-link)

Minor Modes

A minor mode provides features that users may enable or disable independently of the choice of major mode. Minor modes can be enabled individually or in combination. Minor modes would be better named "Generally available, optional feature modes" except that such a name is unwieldy.

A minor mode is not usually a modification of single major mode. For example, Auto Fill mode may be used in any major mode that permits text insertion. To be general, a minor mode must be effectively independent of the things major modes do.

A minor mode is often much more difficult to implement than a major mode. One reason is that you should be able to activate and deactivate minor modes in any order. A minor mode should be able to have its desired effect regardless of the major mode and regardless of the other minor modes in effect.

Often the biggest problem in implementing a minor mode is finding a way to insert the necessary hook into the rest of Emacs. Minor mode keymaps make this easier in Emacs 19 than it used to be.

Minor Mode Conventions: Tips for writing a minor mode.
Keymaps and Minor Modes: How a minor mode can have its own keymap.

Conventions for Writing Minor Modes

There are conventions for writing minor modes just as there are for major modes. Several of the major mode conventions apply to minor modes as well: those regarding the name of the mode initialization function, the names of global symbols, and the use of keymaps and other tables.

In addition, there are several conventions that are specific to minor modes.

Make a variable whose name ends in `-mode' to represent the minor mode. Its value should enable or disable the mode (nil to disable; anything else to enable.) We call this the mode variable. This variable is used in conjunction with the minor-mode-alist to display the minor mode name in the mode line. It can also enable or disable a minor mode keymap. Individual commands or hooks can also check the variable's value. If you want the minor mode to be enabled separately in each buffer, make the variable buffer-local.
Define a command whose name is the same as the mode variable. Its job is to enable and disable the mode by setting the variable. The command should accept one optional argument. If the argument is nil, it should toggle the mode (turn it on if it is off, and off if it is on). Otherwise, it should turn the mode on if the argument is a positive integer, a symbol other than nil or -, or a list whose CAR is such an integer or symbol; it should turn the mode off otherwise. Here is an example taken from the definition of overwrite-mode. It shows the use of overwrite-mode as a variable that enables or disables the mode's behavior, and also shows the proper way to toggle, enable or disable the minor mode based on the raw prefix argument value.
```
(setq overwrite-mode
      (if (null arg) (not overwrite-mode)
        (> (prefix-numeric-value arg) 0)))
```
Add an element to minor-mode-alist for each minor mode (see section Variables Used in the Mode Line). This element should be a list of the following form:
```
(mode-variable string)
```
Here mode-variable is the variable that controls enabling of the minor mode, and string is a short string, starting with a space, to represent the mode in the mode line. These strings must be short so that there is room for several of them at once. When you add an element to minor-mode-alist, use assq to check for an existing element, to avoid duplication. For example:
```
(or (assq 'leif-mode minor-mode-alist)
    (setq minor-mode-alist
          (cons '(leif-mode " Leif") minor-mode-alist)))
```

Keymaps and Minor Modes

As of Emacs version 19, each minor mode can have its own keymap, which is active when the mode is enabled. See section Active Keymaps. To set up a keymap for a minor mode, add an element to the alist minor-mode-map-alist.

One use of minor mode keymaps is to modify the behavior of certain self-inserting characters so that they do something else as well as self-insert. In general, this is the only way to do that, since the facilities for customizing self-insert-command are limited to special cases (designed for abbrevs and Auto Fill mode). (Do not try substituting your own definition of self-insert-command for the standard one. The editor command loop handles this function specially.)

Variable: minor-mode-map-alist

This variable is an alist of elements that look like this:

(variable . keymap)

where variable is the variable that indicates whether the minor mode is enabled, and keymap is the keymap. The keymap keymap is active whenever variable has a non-nil value.

Note that elements of minor-mode-map-alist do not have the same structure as elements of minor-mode-alist. The map must be the CDR of the element; a list with the map as the second element will not do.

What's more, the keymap itself must appear in the CDR. It does not work to store a variable in the CDR and make the map the value of that variable.

When more than one minor mode keymap is active, their order of priority is the order of minor-mode-map-alist. But you should design minor modes so that they don't interfere with each other. If you do this properly, the order will not matter.

Mode Line Format

Each Emacs window (aside from minibuffer windows) includes a mode line, which displays status information about the buffer displayed in the window. The mode line contains information about the buffer, such as its name, associated file, depth of recursive editing, and the major and minor modes.

This section describes how the contents of the mode line are controlled. It is in the chapter on modes because much of the information displayed in the mode line relates to the enabled major and minor modes.

mode-line-format is a buffer-local variable that holds a template used to display the mode line of the current buffer. All windows for the same buffer use the same mode-line-format and the mode lines will appear the same (except for scrolling percentages and line numbers).

The mode line of a window is normally updated whenever a different buffer is shown in the window, or when the buffer's modified-status changes from nil to t or vice-versa. If you modify any of the variables referenced by mode-line-format (see section Variables Used in the Mode Line), you may want to force an update of the mode line so as to display the new information.

Function: force-mode-line-update: Force redisplay of the current buffer's mode line.

The mode line is usually displayed in inverse video; see mode-line-inverse-video in section Inverse Video.

Mode Line Data: The data structure that controls the mode line.
Mode Line Variables: Variables used in that data structure.
%-Constructs: Putting information into a mode line.

The Data Structure of the Mode Line

The mode line contents are controlled by a data structure of lists, strings, symbols, and numbers kept in the buffer-local variable mode-line-format. The data structure is called a mode line construct, and it is built in recursive fashion out of simpler mode line constructs.

Variable: mode-line-format: The value of this variable is a mode line construct with overall responsibility for the mode line format. The value of this variable controls which other variables are used to form the mode line text, and where they appear.

A mode line construct may be as simple as a fixed string of text, but it usually specifies how to use other variables to construct the text. Many of these variables are themselves defined to have mode line constructs as their values.

The default value of mode-line-format incorporates the values of variables such as mode-name and minor-mode-alist. Because of this, very few modes need to alter mode-line-format. For most purposes, it is sufficient to alter the variables referenced by mode-line-format.

A mode line construct may be a list, a symbol, or a string. If the value is a list, each element may be a list, a symbol, or a string.

string: A string as a mode line construct is displayed verbatim in the mode line except for %-constructs. Decimal digits after the % specify the field width for space filling on the right (i.e., the data is left justified). See section %-Constructs in the Mode Line.
symbol: A symbol as a mode line construct stands for its value. The value of symbol is used as a mode line construct, in place of symbol. However, the symbols t and nil are ignored; so is any symbol whose value is void. There is one exception: if the value of symbol is a string, it is displayed verbatim: the %-constructs are not recognized.
(string rest...) or (list rest...): A list whose first element is a string or list means to process all the elements recursively and concatenate the results. This is the most common form of mode line construct.
(symbol then else): A list whose first element is a symbol is a conditional. Its meaning depends on the value of symbol. If the value is non-nil, the second element, then, is processed recursively as a mode line element. But if the value of symbol is nil, the third element, else, is processed recursively. You may omit else; then the mode line element displays nothing if the value of symbol is nil.
(width rest...): A list whose first element is an integer specifies truncation or padding of the results of rest. The remaining elements rest are processed recursively as mode line constructs and concatenated together. Then the result is space filled (if width is positive) or truncated (to -width columns, if width is negative) on the right. For example, the usual way to show what percentage of a buffer is above the top of the window is to use a list like this: (-3 "%p").

If you do alter mode-line-format itself, the new value should use the same variables that appear in the default value (see section Variables Used in the Mode Line), rather than duplicating their contents or displaying the information in another fashion. This way, customizations made by the user, by libraries (such as display-time) and by major modes via changes to those variables remain effective.

Here is an example of a mode-line-format that might be useful for shell-mode, since it contains the hostname and default directory.

(setq mode-line-format
  (list ""
   'mode-line-modified
   "%b--" 
   (getenv "HOST")      ; One element is not constant.
   ":" 
   'default-directory
   "   "
   'global-mode-string
   "   %[("
   'mode-name 
   'mode-line-process  
   'minor-mode-alist 
   "%n" 
   ")%]----"
   (line-number-mode "L%l--")
   '(-3 . "%p")
   "-%-"))

Variables Used in the Mode Line

This section describes variables incorporated by the standard value of mode-line-format into the text of the mode line. There is nothing inherently special about these variables; any other variables could have the same effects on the mode line if mode-line-format were changed to use them.

Variable: mode-line-modified

This variable holds the value of the mode-line construct that displays whether the current buffer is modified.

The default value of mode-line-modified is ("--%1*%1*-"). This means that the mode line displays `--**-' if the buffer is modified, `-----' if the buffer is not modified, and `--%%-' if the buffer is read only.

Changing this variable does not force an update of the mode line.

Variable: mode-line-buffer-identification: This variable identifies the buffer being displayed in the window. Its default value is `Emacs: %17b', which means that it displays `Emacs:' followed by seventeen characters of the buffer name. You may want to change this in modes such as Rmail that do not behave like a "normal" Emacs.

Variable: global-mode-string

This variable holds a mode line spec that appears in the mode line by default, just after the buffer name. The command display-time sets global-mode-string to refer to the variable display-time-string, which holds a string containing the time and load information.

The `%M' construct substitutes the value of global-mode-string, but this is obsolete, since the variable is included directly in the mode line.

Variable: mode-name: This buffer-local variable holds the "pretty" name of the current buffer's major mode. Each major mode should set this variable so that the mode name will appear in the mode line.

Variable: minor-mode-alist

This variable holds an association list whose elements specify how the mode line should indicate that a minor mode is active. Each element of the minor-mode-alist should be a two-element list:

(minor-mode-variable mode-line-string)

More generally, mode-line-string can be any mode line spec. It appears in the mode line when the value of minor-mode-variable is non-nil, and not otherwise. These strings should begin with spaces so that they don't run together. Conventionally, the minor-mode-variable for a specific mode is set to a non-nil value when that minor mode is activated.

The default value of minor-mode-alist is:

minor-mode-alist
=> ((abbrev-mode " Abbrev") 
    (overwrite-mode " Ovwrt") 
    (auto-fill-function " Fill")         
    (defining-kbd-macro " Def"))

(In earlier Emacs versions, auto-fill-function was called auto-fill-hook.)

minor-mode-alist is not buffer-local. The variables mentioned in the alist should be buffer-local if the minor mode can be enabled separately in each buffer.

Variable: mode-line-process: This buffer-local variable contains the mode line information on process status in modes used for communicating with subprocesses. It is displayed immediately following the major mode name, with no intervening space. For example, its value in the `*shell*' buffer is (": %s"), which allows the shell to display its status along with the major mode as: `(Shell: run)'. Normally this variable is nil.

Variable: default-mode-line-format

This variable holds the default mode-line-format for buffers that do not override it. This is the same as

(default-value
'mode-line-format)

The default value of default-mode-line-format is:

(""
 mode-line-modified
 mode-line-buffer-identification
 "   "
 global-mode-string
 "   %[("
 mode-name 
 minor-mode-alist 
 "%n" 
 mode-line-process
 ")%]----"
 (-3 . "%p")
 "-%-")

Variable: vc-mode: The variable vc-mode, local in each buffer, records whether the buffer's visited file is maintained with version control, and, if so, which kind. Its value is nil for no version control, or a string that appears in the mode line.

`%`-Constructs in the Mode Line

The following table lists the recognized %-constructs and what they mean. In any construct except `%%', you can add a decimal integer after the `%' to specify how many characters to display.

%b: The current buffer name, obtained with the buffer-name function. See section Buffer Names.
%f: The visited file name, obtained with the buffer-file-name function. See section Buffer File Name.
%*: `%' if the buffer is read only (see buffer-read-only);
`*' if the buffer is modified (see buffer-modified-p);
`-' otherwise. See section Buffer Modification.
%+: `*' if the buffer is modified, and `-' otherwise.
%s: The status of the subprocess belonging to the current buffer, obtained with process-status. See section Process Information.
%p: The percent of the buffer above the top of window, or `Top', `Bottom' or `All'.
%P: The percentage of the buffer text that is above the bottom of the window (which includes the text visible in the window, as well as the text above the top), plus `Top' if the top of the buffer is visible on screen; or `Bottom' or `All'.
%n: `Narrow' when narrowing is in effect; nothing otherwise (see narrow-to-region in section Narrowing).
%[: An indication of the depth of recursive editing levels (not counting minibuffer levels): one `[' for each editing level. See section Recursive Editing.
%]: One `]' for each recursive editing level (not counting minibuffer levels).
%%: The character `%'---this is how to include a literal `%' in a string in which %-constructs are allowed.
%-: Dashes sufficient to fill the remainder of the mode line.

The following two %-constructs are still supported, but they are obsolete, since you can get the same results with the variables mode-name and global-mode-string.

%m: The value of mode-name.
%M: The value of global-mode-string. Currently, only display-time modifies the value of global-mode-string.

Hooks

A hook is a variable where you can store a function or functions to be called on a particular occasion by an existing program. Emacs provides hooks for the sake of customization. Most often, hooks are set up in the `.emacs' file, but Lisp programs can set them also. See section Standard Hooks, for a list of standard hook variables.

Most of the hooks in Emacs are normal hooks. These variables contain lists of functions to be called with no arguments. The reason most hooks are normal hooks is so that you can use them in a uniform way. You can always tell when a hook is a normal hook, because its name ends in `-hook'.

The recommended way to add a hook function to a normal hook is by calling add-hook (see below). The hook functions may be any of the valid kinds of functions that funcall accepts (see section What Is a Function?). Most normal hook variables are initially void; add-hook knows how to deal with this.

As for abnormal hooks, those whose names end in `-function' have a value that is a single function. Those whose names end in `-hooks' have a value that is a list of functions. Any hook that is abnormal is abnormal because a normal hook won't do the job; either the functions are called with arguments, or their values are meaningful. The name shows you that the hook is abnormal and that you should look at its documentation string to see how to use it properly.

Most major modes run hooks as the last step of initialization. This makes it easy for a user to customize the behavior of the mode, by overriding the local variable assignments already made by the mode. But hooks are used in other contexts too. For example, the hook suspend-hook runs just before Emacs suspends itself (see section Suspending Emacs).

Here's an expression you can put in your `.emacs' file to turn on Auto Fill mode when in Lisp Interaction mode:

(add-hook 'lisp-interaction-mode-hook 'turn-on-auto-fill)

The next example shows how to use a hook to customize the way Emacs formats C code. (People often have strong personal preferences for one format or another.) Here the hook function is an anonymous lambda expression.

(add-hook 'c-mode-hook 
  (function (lambda ()
              (setq c-indent-level 4
                    c-argdecl-indent 0
                    c-label-offset -4
                    c-continued-statement-indent 0
                    c-brace-offset 0
                    comment-column 40))))

(setq c++-mode-hook c-mode-hook)

Finally, here is an example of how to use the Text mode hook to provide a customized mode line for buffers in Text mode, displaying the default directory in addition to the standard components of the mode line. (This may cause the mode line to run out of space if you have very long file names or display the time and load.)

(add-hook 'text-mode-hook
  (function (lambda ()
              (setq mode-line-format
                    '(mode-line-modified
                      "Emacs: %14b"
                      "  "  
                      default-directory
                      " "
                      global-mode-string
                      "%[(" 
                      mode-name 
                      minor-mode-alist 
                      "%n" 
                      mode-line-process  
                      ") %]---"
                      (-3 . "%p")
                      "-%-")))))

At the appropriate time, Emacs uses the run-hooks function to run particular hooks. This function calls the hook functions you have added with add-hooks.

Function: run-hooks &rest hookvar

This function takes one or more hook variable names as arguments, and runs each hook in turn. Each hookvar argument should be a symbol that is a hook variable. These arguments are processed in the order specified.

If a hook variable has a non-nil value, that value may be a function or a list of functions. If the value is a function (either a lambda expression or a symbol with a function definition), it is called. If it is a list, the elements are called, in order. The hook functions are called with no arguments.

For example, here's how emacs-lisp-hooks runs its mode hook:

(run-hooks 'emacs-lisp-mode-hook)

Function: add-hook hook function &optional append

This function is the handy way to add function function to hook variable hook. The argument function may be any valid Lisp function with the proper number of arguments. For example,

(add-hook 'text-mode-hook 'my-text-hook-function)

adds my-text-hook-function to the hook called text-mode-hook.

You can use add-hook for abnormal hooks as well as for normal hooks.

It is best to design your hook functions so that the order in which they are executed does not matter. Any dependence on the order is "asking for trouble." However, the order is predictable: normally, function goes at the front of the hook list, so it will be executed first (barring another add-hook call).

If the optional argument append is non-nil, the new hook function goes at the end of the hook list and will be executed last.

Function: remove-hook hook function: This function removes function from the hook variable hook.

Go to the first, previous, next, last section, table of contents.