### /u/sy/beebe/wkkernels-rmax.awk, Sat Sep  6 12:09:03 2025
### Edit by Nelson H. F. Beebe <beebe@math.utah.edu>
### ====================================================================
### Find and report the largest rmax for each test, using the output of
### a compiled version of wkkernels.c.
###
### Usage:
###	awk -f wkkernels-rmax.awk foo.out
###
### [06-Sep-2025]
### ====================================================================

# /^rmax = 0 ulps/ { next }

/^wk|PI_HALF/	{ WK = $1; gsub("[()]", "", WK) }

/^xmax/	{ xmax = $3 }

/^amax/	{ amax = $3 }

/^rmax/	{
	    r = 0 + $3
	    if (r > (0 + RVAL[WK]))
	    {
		# if (WK ~ /wk_sinh/) print "DEBUG 1: r = ", r, "WK = [", WK, "]", "RMAX[WK] = ", RMAX[WK], "RVAL[WK] = ", RVAL[WK], "$3 = [" $3 "]"
		RVAL[WK] = r
		AMAX[WK] = amax
		XMAX[WK] = xmax
		RMAX[WK] = $3
		# if (WK ~ /wk_sinh/) print "DEBUG 2: r = ", r, "WK = [", WK, "]", "RMAX[WK] = ", RMAX[WK], "RVAL[WK] = ", RVAL[WK], "$3 = [" $3 "]"
	    } 
	}

END   {
    cmd = "sort -t'	' -k2"

    for (key in RMAX)
	printf("%-23s\t%-23s\t%-23s\t%s\n", key, RMAX[key], XMAX[key], AMAX[key]) | cmd

#	printf("%-15s\t%-15s\t%-15s\t%s\n", XMAX[key], AMAX[key], RMAX[key], key) | cmd

    close (cmd)
}