2250hwDec8.html

Math 2250

Homework Solutions for Chapter 10

10.1: 3,7,13 ,19, 21,29,30,37,39 ,40

10.2: 3,5,13,22,23,28,31

10.3: 3,7,17,21,31,37

10.4: 2, 3 ,6, 9 ,11, 15 , 29,36

> with(plots):with(linalg):with(inttrans):

10.1 #3)

> f:=t->exp(3*t+1);
int(f(t)*exp(-s*t),t);

Evaluating the antiderivative at infinity, we get zero for s>3, and subtracting off the value at zero, we get e/(s-3) . Since f(t) was e times exp(3t), this answer is correct according to the Laplace Transform table.

#7) Since f(t)=1-u(t-1), F(s) should equal 1/s - exp(-s)/s. Since f =1 from t=0..1, and is zero for t>1, the Laplace transform integral is just

> Int(1*exp(-s*t),t=0..1): #display integral with capital I
int(1*exp(-s*t),t=0..1); #evaluate it

#13) f(t) = t -2*exp(3t), so F(s) = 1/s^2 -2*(1/(s-3)).

#21) f(t) = t*cos(t).

> F(s)=Int(t*cos(t)*exp(-s*t),t);

You can integrate this by parts, using u=t and dv = cos(t)*exp(-st)*dt, or you can use an integral table or computer software. Your answer will be:

> int(t*cos(t)*exp(-s*t),t);

For s>0, the value of this at infinity is zero, and we subtract off the value at t=0 to get

> (s^2-1)/((s^2+1)^2);

We can check our answer in the back of the book, but since we're in Maple Land we can also just ask for

> laplace(t*cos(t),t,s);

#29) We rewrite F(s) = (5/3)*(3/(s^2 + 9)) -3*(s/(s^2+9)), so f(t) = (5/3)*sin(3*t) - 3*cos(3*t). We check our answer:

> invlaplace((5-3*s)/(s^2+9),s,t);

#30) F(s) = 2*(exp(-3*s)/s, so f(t) = 2*u(t-3). We check our answer:

> invlaplace(2*exp(-3*s)/s,s,t);

#37) f(t) = u(t) - u(t-a), so F(s) = 1/s - exp(-a*s)/s, as claimed.

#39) (b)

> f:= t-> sum(Heaviside(t-n),n=0..infinity);

If (N-1)<t<N, then t-n will be positive for n=0,1,2,...N-1, so for these N values of n the corresponding Heaviside(t-n) will be equal to 1, and for the remaining n>N-1, there is no contribution, so the left hand side of the formula for f will give exactly n, as desired.

(a)

> g:=t->sum(Heaviside(t-n),n=0..10);

> plot(g(t),t=0..10, color=black);

c) The Laplace transform of f(t) is

> (1/s)*Sum(exp(-n*s),n=0..infinity);
#Capital S Sum is intert, lower case
#s sum will try to evaluate it

The sum of a geometric series with first term a and ratio r satisfying |r|<1 is, S= a/(1-r). Our sum has first term 1, and ratio r=exp(-s). So the infinite sum (for s>0) is therefore 1/(1-(exp(-s)), so our final answer is

> (1/s)*sum(exp(-n*s),n=0..infinity);

10.2: #3)

> restart:with(inttrans):with(plots):

Warning, the name changecoords has been redefined

> deqtn:=diff(x(t),t,t) - diff(x(t),t) -2*x(t) = 0;

> laplace(deqtn,t,s);

> subs(laplace(x(t),t,s)=X(s),%);

> subs({x(0)=0,D(x)(0)=2},%);

> solve(%,X(s));

> invlaplace(%,s,t);

I could have gotten this answer by first doing partial fractions:

> convert(2*1/(s^2-s-2),parfrac,s);

#5)

> deqtn:=diff(x(t),t,t) + x(t) = sin(2*t);

> laplace(deqtn,t,s);

> subs({laplace(x(t),t,s)=X(s),x(0)=0,D(x)(0)=0},%);

> solve(%,X(s));

> convert(%,parfrac,s);

> invlaplace(%,s,t);

#13)

> deqtn:={diff(x(t),t) + 2*diff(y(t),t) + x(t) =0,
diff(x(t),t) - diff(y(t),t) + y(t) = 0};

> laplace(%,t,s);

> subs({laplace(x(t),t,s)=X(s),laplace(y(t),t,s)=Y(s),
x(0)=0,y(0)=1},%);

> solve(%,{X(s),Y(s)});

${X(s) = -2*1/(3*s^2-1), Y(s) = (3*s+1)/(3*s^2-1)}$

> invlaplace(%,s,t);

> subs({invlaplace(X(s),s,t)=x(t),invlaplace(Y(s),s,t)=y(t)},%);

The answer would look better if we used cosh and sinh. Rewriting these we see

> x(t)=-(2/sqrt(3))*sinh(t/sqrt(3));
y(t) = cosh(t/sqrt(3)) + (1/sqrt(3))*sinh(t/sqrt(3));

#22) F(s) = (1/s)*(1/(s^2 - 9). The inverse Laplace transform of (1/(s^2-9) is (1/3)sinh(3t). So f(t) equals (by Theorem 2)

> int((1/3)*sinh(3*tau),tau=0..t);

> invlaplace(1/(s*(s^2-9)),s,t);
#check answer

#23) Well, I wouldn't object if you wanted to use partial fractions to do this one. But, using Theorem 2 (twice), we start with F(s) = 1/(s^2-1), which has f(t) = sinh(t). We integrate once to get the inverse Laplace transform of (1/s)*(F(s):

> int(sinh(tau),tau=0..t);

Now repeat, to solve for the inverse Laplace transform of (1/s^2)*F(s):

> int(cosh(tau)-1,tau=0..t);

> invlaplace(1/((s^2)*(s^2-1)),s,t);
#check answer

#28)

> f:=t->t*cos(k*t);

> diff(f(t),t);

> diff(%,t);

> diff(f(t),t,t)+k^2*f(t);

So we see that f(t) solves

> deqtn:=diff(x(t),t,t) + k^2*x(t) = -2*k*sin(k*t);

And f(0)=0, and D(f)(0)=1, so we can find F(s) using our DE trick:

> laplace(deqtn,t,s);

> subs({laplace(x(t),t,s)=F(s),x(0)=0,D(x)(0)=1},%);

> solve(%,F(s));
#this is the answer, note denom is (s^2 + k^2)^2.

#31) As far as I can tell, we only need to use problem 28 and the Laplace formula for sin(kt). Notice that the numerator in #28 can be written as (s^2 + k^2) - 2*k^2, which means that

(s^2 - k^2)/(s^2 + k^2)^2

> (s^2 - k^2)/(s^2 + k^2)^2 = 1/(s^2 + k^2) - 2*k^2/(s^2+k^2)^2;

Take inverse Laplace transform of this equation, calling our unknown function in 31 by the name g(t):

> t*cos(k*t)= (1/k)*sin(k*t) - 2*k^2*g(t);

> solve(%,g(t));

Voila!

10.3 #3) The Laplace transform of sin(3*Pi*t) is 3*Pi/(s^2 + 9*Pi^2). So the Laplace transform of exp(-2*t) times this function is obtained by replacing s with s+2, i.e.

> F(s)=(3*Pi)/((s+2)^2 + 9*Pi^2);

> laplace(exp(-2*t)*sin(3*Pi*t),t,s);
#check our answer

#7)

> F(s)= 1/(s+2)^2;

Since the inverse Laplace transform of 1/s^2 is t, our function is f(t)=exp(-2*t)*t

> invlaplace(1/(s^2+4*s+4),s,t);
#check answer

#17)

> convert(1/(s^4-16),parfrac,s);

>

So we deduce that f(t) = (1/32)*(exp(2*t) - exp(-2*t)) - (1/16)*sin(2*t) = (1/16)*(sinh(2*t) - sin(2*t)).

> invlaplace(1/(s^4-16),s,t);
#check answer

#21)

> convert((s^2+3)/(s^2 + 2*s +2)^2,parfrac,s);

We complete the square in the denominator, and then complete the "linear" in the numerator, and can rewrite this as

> -2*(s+1)/((s+1)^2+1)^2 + 3/((s+1)^2+1)^2 + 1/((s+1)^2+1);

From the translation theorem and tables we deduce that f(t) equals

> exp(-t)*(-2*(t/2)*sin(t) + 3*(1/2)*(sin(t) - t*cos(t)) + sin(t));

> invlaplace((s^2+3)/(s^2 + 2*s +2)^2,s,t);
#check answer

#31)

> deqtn:=diff(x(t),t,t,t) + diff(x(t),t,t) - 6*diff(x(t),t)=0;

> laplace(deqtn,t,s);

> subs({laplace(x(t),t,s)=X(s),x(0)=0,D(x)(0)=1,D(D(x))(0)=1},%);

> solve(%,X(s));

> convert(%,parfrac,s);

> invlaplace(%,s,t);
#answer

#37)

> deqtn:=diff(x(t),t,t) + 4*diff(x(t),t) + 13*x(t)=t*exp(-t);

> laplace(deqtn,t,s);

> subs({laplace(x(t),t,s)=X(s),x(0)=0,D(x)(0)=2},%);

> solve(%,X(s));

> convert(%,parfrac,s);

> invlaplace(%,s,t);
#solution

10.4 #3)

> int(sin(t-tau)*sin(tau),tau=0..t);

#9) F(s) = (1/(s^2 +9))(1/(s^2+9)), so f(t)=(1/3)sin(3t) convolved with (1/3)sin(3t), i.e.

> (1/9)*int(sin(3*(t-tau))*sin(3*tau),tau=0..t);

#15) Theorem 2: take g(t) = -sin(3t), G(s) = -3/(s^2 + 9). Then for f(t)=-t*g(t) = -tsin(3t), we deduce F(s) is the derivative of G(s), i.e.

> diff(-3/(s^2+9),s);

> laplace(t*sin(3*t),t,s);
#check answer

#29)

> deqtn:=t*diff(x(t),t,t) + (t-2)*diff(x(t),t) + x(t)=0;

> laplace(%,t,s);

> subs({laplace(x(t),t,s)=X(s),
diff(laplace(x(t),t,s),s)=diff(X(s),s),
x(0)=0},%);

> %/s;

> simplify(%);

> with(DEtools):
dsolve(-4*X(s)-s*diff(X(s),s)-diff(X(s),s)=0);
#this is a first order separable DE, chapter 1

> invlaplace(C1/(s+1)^4,s,t);

#36)

> restart:with(inttrans):

> deqtn:=diff(x(t),t,t)+4*x(t)=f(t);

> laplace(%,t,s);

> subs({laplace(x(t),t,s)=X(s),laplace(f(t),t,s)=F(s),
x(0)=0,D(x)(0)=0},%);

> solve(%,X(s));

So the convolution theorem says x(t) is the convolution of f(t) with (1/2)sin(2t):

> x(t)=(1/2)*Int(f(t-tau)*sin(2*tau),tau);

END!