### /u/sy/beebe/public_html/html-pretty.awk, Fri Apr  7 12:55:26 1995
### Edit by Nelson H. F. Beebe <beebe@plot79.math.utah.edu>
### ====================================================================
###  @Awk-file{
###     author          = "Nelson H. F. Beebe",
###     version         = "0.05",
###     date            = "17 April 1995",
###     time            = "09:34:07 MDT",
###     filename        = "html-pretty.awk",
###     address         = "Center for Scientific Computing
###                        Department of Mathematics
###                        University of Utah
###                        Salt Lake City, UT 84112
###                        USA",
###     telephone       = "+1 801 581 5254",
###     FAX             = "+1 801 581 4148",
###     checksum        = "18136 847 2880 24100",
###     email           = "beebe@math.utah.edu (Internet)",
###     codetable       = "ISO/ASCII",
###     keywords        = "HTML, prettyprinter, SGML, WWW, World-Wide Web",
###     supported       = "yes",
###     docstring       = "This is a simple HTML file prettyprinter.
###
###                        Usage:
###                           gawk -f html-pretty.awk [-v FILE=name]
###                               [-v INDENT=nnn] [-v MAXLINE=72]
###                        or
###                           nawk -f html-pretty.awk [-v FILE=name]
###                               [-v INDENT=nnn] [-v MAXLINE=72]
###
###                        The optional FILE value sets the input file
###                        name, to override the actual name, or in
###                        the event that input is from standard
###                        input.
###
###                        The optional INDENT value sets the default
###                        indentation (default: 4 spaces per level).
###
###                        The optional MAXLINE value sets the maximum
###                        line length (default: 72).
###
###                        The idea is that each <TAG> ... </TAG> pair
###                        should contain material that is indented
###                        according to the nesting depth of the tags.
###                        However, certain common tags, such as those
###                        to change fonts, are excluded from this
###                        indenting.
###
###                        As with any simple-minded prettyprinter,
###                        especially ones for natural language text,
###                        which rarely conforms to a strict grammar,
###                        you should check the output of the
###                        prettyprinter before replacing the input by
###                        it.  In particular, if your input file
###                        follows the standards imposed by this
###                        prettyprinter, a file difference listing may
###                        be reassuring.  Otherwise, try viewing the
###                        output with one or more World-Wide Web client
###                        programs (arena, hotjava, netscape, xmosaic,
###                        ...).  If you have an SGML parser or
###                        translator, you can use that for checking
###                        too.
###
###                        TO DO:
###
###                        (1) More extensive testing, and perhaps a
###                        validation suite.
###
###                        The checksum field above contains a CRC-16
###                        checksum as the first value, followed by the
###                        equivalent of the standard UNIX wc (word
###                        count) utility output of lines, words, and
###                        characters.  This is produced by Robert
###                        Solovay's checksum utility.",
###  }
###
### ====================================================================

BEGIN	{
	    VERSION = "0.05"		# these MUST match version
	    DATE = "[17-Apr-1995]" 	# and date above
	    initialize()
	    out_banner()
	    do_input()
	}

END	{ wrapup() }

function adjust_level(n)
{
    level += n
    if (level < 0)
	error("negative indentation requested")
}

function base_tag(t)
{
    if (iscomment(t))
	return (t)		# HTML comment
    match(t,/^<\/?[A-Za-z][A-Za-z0-9]*/)
    if ((RLENGTH == 0) || (RSTART != 1))
        error("unmatched HTML tag")
    return (toupper(substr(t,RSTART,RLENGTH)) ">")
}

function check_for_omitted_tag(s, tag)
{
    # SGML allows ending tags to be omitted if it can be determined
    # from context that they should be implicitly supplied.  This
    # unfortunate practice complicates construction of processing
    # tools like this prettyprinter.  The only one that we handle for
    # now is the common case of an omitted end-paragraph tag, </P>.

    # static : paragraph_level

    # print "DEBUG: line_buffer = [" line_buffer "]"
    tag = base_tag(s)		# discard optional key=value args in SGML tag
    if (tag in exclude)
	return
    else if ((tag == "<P>") || (tag ~ /^<H[1-6]>$/))
    {				# then at new paragraph or new section
	for ( ; paragraph_level > 0; paragraph_level--)
	    out_tag("</P>")	# supply missing end-paragraph tags
	if (tag == "<P>")
	    paragraph_level++
    }
    else if (tag == "</P>")
    {
	if (paragraph_level <= 0)
	    error("negative paragraph level")
	paragraph_level--
    }
}

function do_input( token)
{
    while ((token = get_token()) != EOF)
    {
	# print "TOKEN: [" token "]" >"/dev/tty"
	if (substr(token,1,1) == "<")
	{
	    check_for_omitted_tag(token)
	    out_tag(token)
	}
	else if (token == "\n")
	{
	    trim_line()
	    if (line_length() > 0)
	        newline()
	    newline()
	    out_indentation()
	    last_token_was_tag = 0
	}
	else
	    out_word(token)
    }
}

function error(msg)
{
    # global : input_line, last_k

    print FILE ":" FNR ":" msg \
	": [" substr(input_line,1,last_k) "...]" > "/dev/tty"
    wrapup()
    exit (1)
}

function get_char()
{
    # global : input_line, last_k

    if (last_k >= length(input_line))
    {
	if (getline input_line <= 0) # then EOF or error
	    return (EOF)
	last_k = 0
	input_line = input_line "\n"
    }
    return (substr(input_line,++last_k,1))
}

function get_token( c,token)
{
    if (skip_whitespace() > 1)	# adjacent newlines are unmarked-up parbreak
	return ("\n")
    c = get_char()
    if (c == EOF)
	return (EOF)
    else if (c == "<")
	return (normalize_whitespace(get_tag(c)))
    else
	return (get_word(c))
}

function get_tag(c, token)
{
    token = c
    for (;;)
    {
        c = get_char()
        if (c == ">")
	{
	    token = token c
	    break
	}
        else if (c == EOF)
	{
	    token = token ">"	# supply missing delimiter
	    break
	}
	token = token c
    }
    if (iscomment(token))
	return token		# then possibly multiline comment
    else
	return (token)
}

function get_word(c)
{
    token = c
    for (;;)
    {
        c = get_char()
	if (c == EOF)
	    return (token)
	else if (iswhite(c) || (c == "<"))
	{
	    unget_char()
	    return (token)
	}
	token = token c
    }
}

function indentation_size()
{
    return (INDENT * level)
}


function initialize()
{
    # Set defaults for command-line variables.
    if (FILE == "")
	FILE = FILENAME
    if (FILE == "-")
	FILE = ""

    if (INDENT  == "") INDENT = 4
    if (MAXLINE == "") MAXLINE = 72

    EOF = -1			# global end-of-file flag (opaque value)

    # Tags in exclude[] do not cause indentation actions.

    exclude["<ABOVE>"] = 1
    exclude["</ABOVE>"] = 1
    exclude["<B>"] = 1
    exclude["</B>"] = 1
    exclude["<BASE>"] = 1
    exclude["<BELOW>"] = 1
    exclude["</BELOW>"] = 1
    exclude["<BIG>"] = 1
    exclude["</BIG>"] = 1
    exclude["<BOX>"] = 1
    exclude["</BOX>"] = 1
    exclude["<BR>"] = 1
    exclude["<CHANGED>"] = 1
    exclude["<DD>"] = 1
    exclude["<DT>"] = 1
    exclude["<DFN>"] = 1
    exclude["</DFN>"] = 1
    exclude["<EM>"] = 1
    exclude["</EM>"] = 1
    exclude["<HR>"] = 1
    exclude["<I>"] = 1
    exclude["</I>"] = 1
    exclude["<IMG>"] = 1
    exclude["<INPUT>"] = 1
    exclude["<ISINDEX>"] = 1
    exclude["<ITEM>"] = 1
    exclude["<LI>"] = 1
    exclude["<LINK>"] = 1
    exclude["<KDB>"] = 1
    exclude["</KDB>"] = 1
    exclude["<META>"] = 1
    exclude["<NEXTID>"] = 1		# %HTML.Deprecated
    exclude["<OVER>"] = 1
    exclude["<Q>"] = 1
    exclude["</Q>"] = 1
    exclude["<RENDER>"] = 1
    exclude["<ROOT>"] = 1
    exclude["</ROOT>"] = 1
    exclude["<REV>"] = 1
    exclude["</REV>"] = 1
    exclude["<S>"] = 1
    exclude["</S>"] = 1
    exclude["<SMALL>"] = 1
    exclude["</SMALL>"] = 1
    exclude["<STRONG>"] = 1
    exclude["</STRONG>"] = 1
    exclude["<SUB>"] = 1
    exclude["</SUB>"] = 1
    exclude["<SUP>"] = 1
    exclude["</SUP>"] = 1
    exclude["<TAB>"] = 1
    exclude["<TD>"] = 1
    exclude["<TH>"] = 1
    exclude["<TR>"] = 1
    exclude["<TT>"] = 1
    exclude["</TT>"] = 1
    exclude["<U>"] = 1
    exclude["</U>"] = 1

    # Tags in list_tags[] get an extra level of indentation, so that
    # embedded list item tags have their own level.

    list_tags["<DIR>"] = 2		# %HTML.Deprecated
    list_tags["</DIR>"] = 2		# %HTML.Deprecated
    list_tags["<DL>"] = 2
    list_tags["</DL>"] = 2
    list_tags["<MENU>"] = 2		# %HTML.Deprecated
    list_tags["</MENU>"] = 2		# %HTML.Deprecated
    list_tags["<OL>"] = 2
    list_tags["</OL>"] = 2
    list_tags["<UL>"] = 2
    list_tags["</UL>"] = 2

    # Tags in list_item[] get outdented one level inside lists.

    list_item["<DD>"] = 1
    list_item["<DT>"] = 1
    list_item["<LI>"] = 1

    # Tags in newline_around[] get a newline inserted before and after
    # them, unless they are at end-of-line already.

    newline_around["<A>"] = 1
    newline_around["</A>"] = 1
    newline_around["<ABBREV>"] = 1
    newline_around["</ABBREV>"] = 1
    newline_around["<ABSTRACT>"] = 1
    newline_around["</ABSTRACT>"] = 1
    newline_around["<ACRONYM>"] = 1
    newline_around["</ACRONYM>"] = 1
    newline_around["<ADDED>"] = 1
    newline_around["</ADDED>"] = 1
    newline_around["<ADDRESS>"] = 1
    newline_around["</ADDRESS>"] = 1
    newline_around["<ARG>"] = 1
    newline_around["</ARG>"] = 1
    newline_around["<AROW>"] = 1
    newline_around["</AROW>"] = 1
    newline_around["<ARRAY>"] = 1
    newline_around["</ARRAY>"] = 1
    newline_around["<AU>"] = 1
    newline_around["</AU>"] = 1
    newline_around["<BASE>"] = 1
    newline_around["<BODY>"] = 1
    newline_around["</BODY>"] = 1
    newline_around["<BLOCKQUOTE>"] = 1
    newline_around["</BLOCKQUOTE>"] = 1
    newline_around["<BQ>"] = 1
    newline_around["</BQ>"] = 1
    newline_around["<CAPTION>"] = 1
    newline_around["</CAPTION>"] = 1
    newline_around["<CDATA>"] = 1	# %HTML.Deprecated
    newline_around["</CDATA>"] = 1	# %HTML.Deprecated
    newline_around["<CHANGED>"] = 1
    newline_around["<CITE>"] = 1
    newline_around["</CITE>"] = 1
    newline_around["<CMD>"] = 1
    newline_around["</CMD>"] = 1
    newline_around["<DD>"] = 1
    newline_around["<DIR>"] = 1		# %HTML.Deprecated
    newline_around["</DIR>"] = 1	# %HTML.Deprecated
    newline_around["<DIV1>"] = 1
    newline_around["</DIV1>"] = 1
    newline_around["<DIV2>"] = 1
    newline_around["</DIV2>"] = 1
    newline_around["<DIV3>"] = 1
    newline_around["</DIV3>"] = 1
    newline_around["<DIV4>"] = 1
    newline_around["</DIV4>"] = 1
    newline_around["<DIV5>"] = 1
    newline_around["</DIV5>"] = 1
    newline_around["<DIV6>"] = 1
    newline_around["</DIV6>"] = 1
    newline_around["<DL>"] = 1
    newline_around["</DL>"] = 1
    newline_around["<DT>"] = 1
    newline_around["<FIG>"] = 1
    newline_around["</FIG>"] = 1
    newline_around["<FN>"] = 1
    newline_around["</FN>"] = 1
    newline_around["<FOOTNOTE>"] = 1
    newline_around["</FOOTNOTE>"] = 1
    newline_around["<FORM>"] = 1
    newline_around["</FORM>"] = 1
    newline_around["<H1>"] = 1
    newline_around["</H1>"] = 1
    newline_around["<H2>"] = 1
    newline_around["</H2>"] = 1
    newline_around["<H3>"] = 1
    newline_around["</H3>"] = 1
    newline_around["<H4>"] = 1
    newline_around["</H4>"] = 1
    newline_around["<H5>"] = 1
    newline_around["</H5>"] = 1
    newline_around["<H6>"] = 1
    newline_around["</H6>"] = 1
    newline_around["<HEAD>"] = 1
    newline_around["</HEAD>"] = 1
    newline_around["<HIDE>"] = 1
    newline_around["</HIDE>"] = 1
    newline_around["<HR>"] = 1
    newline_around["<HTML>"] = 1
    newline_around["</HTML>"] = 1
    newline_around["<INPUT>"] = 1
    newline_around["<ISINDEX>"] = 1
    newline_around["<ITEM>"] = 1
    newline_around["<LANG>"] = 1
    newline_around["</LANG>"] = 1
    newline_around["<LH>"] = 1
    newline_around["</LH>"] = 1
    newline_around["<LI>"] = 1
    newline_around["<LINK>"] = 1
    newline_around["<MARGIN>"] = 1
    newline_around["</MARGIN>"] = 1
    newline_around["<MATH>"] = 1
    newline_around["</MATH>"] = 1
    newline_around["<MENU>"] = 1 	# %HTML.Deprecated
    newline_around["</MENU>"] = 1	# %HTML.Deprecated
    newline_around["<MESSAGE>"] = 1
    newline_around["</MESSAGE>"] = 1
    newline_around["<META>"] = 1
    newline_around["<NEXTID>"] = 1	# %HTML.Deprecated
    newline_around["<NOTE>"] = 1
    newline_around["</NOTE>"] = 1
    newline_around["<OL>"] = 1
    newline_around["</OL>"] = 1
    newline_around["<OPTION>"] = 1
    newline_around["</OPTION>"] = 1
    newline_around["<OVERLAY>"] = 1
    newline_around["</OVERLAY>"] = 1
    newline_around["<P>"] = 1
    newline_around["</P>"] = 1
    newline_around["<PERSON>"] = 1
    newline_around["</PERSON>"] = 1
    newline_around["<QUOTE>"] = 1
    newline_around["</QUOTE>"] = 1
    newline_around["<RENDER>"] = 1
    newline_around["<REMOVED>"] = 1
    newline_around["</REMOVED>"] = 1
    newline_around["<SELECT>"] = 1
    newline_around["</SELECT>"] = 1
    newline_around["<STYLE>"] = 1
    newline_around["<STYLES>"] = 1
    newline_around["<TABLE>"] = 1
    newline_around["</TABLE>"] = 1
    newline_around["<TEXTAREA>"] = 1
    newline_around["</TEXTAREA>"] = 1
    newline_around["<TITLE>"] = 1
    newline_around["</TITLE>"] = 1
    newline_around["<UL>"] = 1
    newline_around["</UL>"] = 1
    newline_around["<XMP>"] = 1
    newline_around["</XMP>"] = 1

    # Tags in newline_after[] get a newline inserted after them,
    # unless they are at end-of-line already.

    newline_after["<BR>"] = 1
    newline_after["</LISTING>"] = 1
    newline_after["</PRE>"] = 1

    # Tags in newline_before[] get a newline before them, unless they
    # are the first output token on the current line.

    newline_before["<LISTING>"] = 1
    newline_before["<PLAINTEXT>"] = 1
    newline_before["<PRE>"] = 1

    # Tags in no_space_before[] have any preceding space deleted,
    # unless they are the first token on the current line.

    no_space_before["<BR>"] = 1
    no_space_before["</B>"] = 1
    no_space_before["</CODE>"] = 1
    no_space_before["</DFN>"] = 1
    no_space_before["</EM>"] = 1
    no_space_before["</I>"] = 1
    no_space_before["</KDB>"] = 1
    no_space_before["</SAMP>"] = 1
    no_space_before["</STRONG>"] = 1
    no_space_before["</VAR>"] = 1

    # Tags in space_after[] get a single space after them.  This is
    # not always the right thing to do, for example, if punctuation
    # follows.  The variable last_token_was_tag fixes this in most
    # cases.

    space_after["</B>"] = 1
    space_after["</BIG>"] = 1
    space_after["</CODE>"] = 1
    space_after["</DFN>"] = 1
    space_after["</EM>"] = 1
    space_after["</I>"] = 1
    space_after["</KBD>"] = 1
    space_after["</Q>"] = 1
    space_after["</REV>"] = 1
    space_after["</S>"] = 1
    space_after["</SAMP>"] = 1
    space_after["</SMALL>"] = 1
    space_after["</STRONG>"] = 1
    space_after["</TT>"] = 1
    space_after["</U>"] = 1
    space_after["</VAR>"] = 1

    # Tags in space_before[] get a single space before them, unless
    # they are the first token on the current line.

    space_before["<B>"] = 1
    space_before["<BIG>"] = 1
    space_before["<CODE>"] = 1
    space_before["<DFN>"] = 1
    space_before["<EM>"] = 1
    space_before["<I>"] = 1
    space_before["<KBD>"] = 1
    space_before["<OVER>"] = 1
    space_before["<Q>"] = 1
    space_before["<REV>"] = 1
    space_before["<S>"] = 1
    space_before["<SAMP>"] = 1
    space_before["<SMALL>"] = 1
    space_before["<STRONG>"] = 1
    space_before["<TAB>"] = 1
    space_before["<TT>"] = 1
    space_before["<U>"] = 1
    space_before["<VAR>"] = 1

    # Math mode (HTML 3.0) spacing

    space_after["</ABOVE>"] = 1
    space_after["</BELOW>"] = 1
    space_after["</BOX>"] = 1
    space_after["</ROOT>"] = 1
    space_after["</SUB>"] = 1
    space_after["</SUP>"] = 1

    space_before["<ABOVE>"] = 1
    space_before["<BELOW>"] = 1
    space_before["<BOX>"] = 1
    space_before["<ROOT>"] = 1
    space_before["<SUB>"] = 1
    space_before["<SUP>"] = 1

    # Tags in verbatim_tags[] require special handling of the input,
    # since spacing is then significant

    verbatim_tags["<CDATA>"] = 1	# %HTML.Deprecated
    verbatim_tags["<LISTING>"] = 1
    verbatim_tags["<PLAINTEXT>"] = 1
    verbatim_tags["<PRE>"] = 1
    verbatim_tags["<XMP>"] = 1
}

function iscomment(t)
{
    return (substr(t,1,4) == "<!--")
}

function iswhite(c)
{
    # Should include \f and \v, but nawk doesn't have them; gawk does.
    return (index("\t\r\n ",c) > 0)
}

function line_length()
{
    return (length(line_buffer))
}

function newline()
{
    trim_line()
    # printf("%s%s\n", prefix, line_buffer)
    print line_buffer
    line_buffer = ""
}

function normalize_whitespace(s)
{
    # Should include \f and \v, but nawk doesn't have them; gawk does.
    gsub(/[ \t\r\n]+/," ",s)
    return (s)
}

function out_banner(  the_host, the_person, the_time, the_user)
{
    "uname -n" | getline the_host
    if (the_host == "")
	"hostname" | getline the_host

    "date" | getline the_time

    "echo $LOGNAME" | getline the_user

    "cat /etc/passwd | awk -F: '/^" the_user ":/ {print $5}' | head -1" | \
	getline the_person
    if (the_person == "")
	"ypcat passwd | awk -F: '/^" the_user ":/ {print $5}' | head -1" | \
	    getline the_person

    print "<!-- -*-html-*- -->"	# for GNU Emacs mode selection
    if (FILE != "")
	print "<!--", FILE, "-->"
    print "<!-- Prettyprinted by html-pretty.awk version",
	VERSION, DATE, "-->"
    print "<!-- on", the_time, "-->"
    print "<!-- for", the_person, "("  the_user "@" the_host ") -->"
    print ""
}

function out_indentation()
{
    # Supply a newline with leading indentation, omitting the
    # newline if the line is already empty.

    trim_line()
    if (line_length() > 0)
	newline()
    prefix = sprintf("%2d:",level)
    out_leading_blanks(indentation_size())
}

function out_leading_blanks(nblanks, k)
{
    # printf("%3d:", level)
    for (k = 1; k <= nblanks; ++k)
	line_buffer = line_buffer " "
}

function out_string(s)
{
    if ((length(s) + line_length()) > MAXLINE)
	out_indentation()
    if ((line_length() == indentation_size()) && (s ~ /^[ ]+$/))
	return			# discard spaces at beginning of line
    line_buffer = line_buffer s
}

function out_tag(s, tag)
{
    last_token_was_tag = 1

    # print "DEBUG: line_buffer = [" line_buffer "]"
    tag = base_tag(s)		# discard optional key=value args in SGML tag

    if (iscomment(s))		# keep all comments on separate lines
    {
	out_string(s)
	newline()
	return
    }

    s = standardize_tag(s,tag)

    # print "DEBUG: tag =", tag
    if (!(tag in exclude) && (substr(tag,2,1) == "/")) # then have </TAG>
	adjust_level((tag in list_tags) ? -list_tags[tag] : -1)

    # print "DEBUG:",tag

    if (tag in list_item)
	adjust_level(-list_item[tag])

    if ( (tag in newline_before) || (tag in newline_around) )
	out_indentation()
    else if (tag in space_before)
    {
	trim_line()
	out_string(" ")
    }
    else if ((tag in no_space_before) && (line_length() > indentation_size()))
	trim_line()

    if (line_length() < indentation_size())
	out_indentation()

    out_string(s)

    if (tag in list_item)
	adjust_level(list_item[tag])

    # print "DEBUG:", tag, "in newline_after =",(tag in newline_after)
    if (!(tag in exclude) && \
	(substr(tag,2,1) != "/") && \
	(substr(tag,2,1) != "!"))
	adjust_level((tag in list_tags) ? list_tags[tag] : 1)
    if ( (tag in newline_after) || (tag in newline_around) )
	out_indentation()
    else if (tag in space_after)
	out_string(" ")

    # Verbatim sections require special handling, with all white space
    # preserved.  Consequently, if we have reached the beginning of
    # such a section, we let out_verbatim() handle the output of the
    # complete section, and its end tag, if any.

    if (tag in verbatim_tags)
	out_verbatim(tag)
}

function out_verbatim(start_tag, c,tag,uc_tag)
{
    # <CDATA> ... </CDATA> -- copy intact (%HTML.Deprecated)
    # <PRE> ... </PRE> -- copy intact
    # <LISTING> ... </LISTING> -- copy intact
    # <PLAINTEXT> ... -- copy to end-of-file (there is no </PLAINTEXT>!)
    # <XMP> ... </XMP> -- copy intact


    printf("%s", line_buffer)	# output pending line WITHOUT newline
    line_buffer = ""

    for (;;)
    {
	c = get_char()
	if (c == EOF)
	    return
	if (c == "<")
	{
	    tag = get_tag(c)
	    uc_tag = toupper(tag)
	    if ( ((start_tag == "<LISTING>") && (uc_tag == "</LISTING>")) ||
		 ((start_tag == "<PRE>") && (uc_tag == "</PRE>")) ||
		 ((start_tag == "<XMP>") && (uc_tag == "</XMP>")) )
	    {
		printf("%s", uc_tag)
		if ((uc_tag in newline_after) || (uc_tag in newline_around))
		    print ""
		adjust_level(-1)
		return
	    }
	    else
		printf("%s", tag)
	}
	else
	    printf("%s", c)
    }
}


function out_word(s)
{
    if (last_token_was_tag && (index(",.;:!?",substr(s,1,1)) > 0))
	trim_line()		# delete space between tag and punctuation

    last_token_was_tag = 0

    # print "DEBUG: line_buffer = [" line_buffer "]"
    out_string(s)
    out_string(" ")
    if ((length(s) > 1) && (substr(s,length(s)-1,2) ~ /[A-Z][.]/))
	;		# no extra space after initials
    else if ((length(s) > 3) && (substr(s,length(s)-3,4) ~ /i[.]e[.]/))
	;		# no extra space after "i.e."
    else if ((length(s) > 3) && (substr(s,length(s)-3,4) ~ /e[.]g[.]/))
	;		# no extra space after "e.g."
    else if ((length(s) > 2) && (substr(s,length(s)-2,3) ~ /cf[.]/))
	;		# no extra space after "cf."
    else if (substr(s,length(s),1) ~ /[.;:!?]/)
	out_string(" ")	# supply extra space after punctuation
}

function skip_whitespace( c,nl)
{				# return number of newlines seen
    for (nl = 0; (c = get_char()) && (c != EOF) && iswhite(c); )
    {
	if (c == "\n")
	    nl++
    }
    if (c != EOF)
	unget_char()
    return (nl)
}

function standardize_tag(s,tag, k)
{
    # Normalize tags to consistent letter case.
    if (length(s) > length(tag))
	s = substr(tag,1,length(tag)-1) substr(s,length(tag))
    else
	s = tag
    for (k = 1; k < length(s); )
    {				# convert "key = value" to "KEY = value"
	match(substr(s,k),/[A-Za-z]+ *=/)
	if ((RLENGTH <= 0) || (RSTART <= 0))
	    break
	k = k - 1 + RSTART
	s = substr(s,1,k-1) toupper(substr(s,k,RLENGTH)) substr(s,k+RLENGTH)
	k += RLENGTH
    }
    return (s)
}

########################################################################
# If your nawk lacks toupper() (older ones do), change this name from  #
# Toupper to toupper.  We prefer the builtin one when available,       #
# because it is MUCH more efficient.                                   #
########################################################################
function Toupper(s, k,n,t)
{
    t = ""
    for (k = 1; k <= length(s); ++k)
    {
	n = index("abcdefghijklmnopqrstuvwxyz", substr(s,k,1))
	if (n > 0)
	    t = t substr("ABCDEFGHIJKLMNOPQRSTUVWXYZ", n, 1)
	else
	    t = t substr(s,k,1)
    }
    return t
}

function trim_line()
{
    sub(/[ \t]+$/,"",line_buffer)
}

function unget_char()
{
    # global : last_k
    if (last_k <= 0)
       error("no character to unget")
    last_k--
}

function wrapup()
{
    trim_line()
    if (line_length() > 0)
	print line_buffer
}